build.gradle

plugins {
    id 'java'
    id 'application'
}

tasks.withType(JavaCompile).configureEach {
    //options.release = 23
}

ext.moduleName = 'org.bitcoinj.secp.examples'

dependencies {
    implementation project(':secp-api')
    runtimeOnly project(':secp-bouncy')
    runtimeOnly project(':secp-ffm')
}

jar {
    inputs.property("moduleName", moduleName)
    manifest {
        attributes  'Implementation-Title': 'Example secp256k1-jdk Apps',
                'Implementation-Version': archiveVersion.get()
    }
}

application {
    mainModule = 'org.bitcoinj.secp.examples'
    mainClass = 'org.bitcoinj.secp.examples.Schnorr'
}

def userHome = System.getProperty("user.home")
def javaLibraryPath = findProperty("javaPath") ?: "${userHome}/.nix-profile/lib"

run {
    systemProperty "java.library.path", javaLibraryPath
    jvmArgs += '--enable-native-access=org.bitcoinj.secp.ffm'
}

tasks.register('runEcdsa', JavaExec) {
    javaLauncher = javaToolchains.launcherFor {
        languageVersion = JavaLanguageVersion.of(javaToolchainVersion)
    }
    systemProperty "java.library.path", javaLibraryPath
    classpath = sourceSets.main.runtimeClasspath
    mainModule = 'org.bitcoinj.secp.examples'
    mainClass = 'org.bitcoinj.secp.examples.Ecdsa'
    jvmArgs += '--enable-native-access=org.bitcoinj.secp.ffm'
}