ASP.NET_CountOfLinesPerFile.bat

REM Developed by Deepak Mourya, Information Security Consultant
@echo off
cls
echo.
echo.
echo Set proper and correct Application Folder Path (for ASP.NET application only):
echo Else output will be ***WRONG*** !!!
echo.
echo *** Enter application path within the double quotes and press enter key ***
echo.
set appPath=""
set /p appPath=
if %appPath% == "" (goto :eof)
echo.
REM deleting old files
IF exist FileList.txt (del FileList.txt)
IF exist CountOfLinesPerFile.txt (del CountOfLinesPerFile.txt)
IF exist Result.txt (del Result.txt)
echo deleted old files (old files which was generated by this tool only)...
echo.

REM creating file list for ASP.NET application only
dir /S /B %appPath% | findstr /I "aspx master asax ascx config cs vb" | findstr /V /I "csv css" > FileList.txt
echo created list of all files...
echo.

echo counting is started...
echo.
REM starting count of lines and push them in csv file.
for /f "tokens=*" %%x in ('type "FileList.txt"') do (
	echo %%x >> CountOfLinesPerFile.txt
	findstr /R /N "^" "%%x" | find /C ":" >> CountOfLinesPerFile.txt	
	findstr /R /N "^" "%%x" | find /C ":" >> CountOfLinesPerFile.csv
)
echo.

IF NOT exist CountOfLinesPerFile.csv ( 
echo ERROR: 
echo There is an error due to application path or it is not a valid ASP.NET application
goto :eof
)
echo counting completed...

REM sum count of all lines and display them
set /a sum=0
for /f "tokens=* delims= " %%a in (CountOfLinesPerFile.csv) do (
	set /a sum+= %%a
	)
echo Toatl count of lines in all files: %sum% 
del CountOfLinesPerFile.csv
echo.

REM creating output file
echo Result: > Result.txt
echo -------- >> Result.txt
echo. >> Result.txt
date /t >> Result.txt
time /t >> Result.txt
echo. >> Result.txt
Echo Application Path: %appPath% >> Result.txt
echo.  >> Result.txt
echo Toatl count of lines in all files: %sum%  >> Result.txt
echo. >> Result.txt
pause