pron2.lse

1* PROGRAMME DE RECHERCHE DE PRONOMS DANS UN TEXTE
2* ERIC LE BRAS  4.2                               N.218
4 CHAINE NOM,TEX,TEXT,PL,NBPR0,TITRE,OTEUR,CAT,PROCA,CATE,QUIZ
5 TZ_1;BX_0;ER_0
6 TABLEAU P[7]
7 AFFICHER 'NOM DU FICHIER TEXTE : ';LIRE NOM
55 AFFICHER[5/,'TU VAS MAINTENANT RELEVER ET TAPER LES PRONOMS DANS L"ORDRE']
56 AFFICHER 'OU ILS SE TROUVENT DANS LE TEXTE. TAPE APRES CHAQUE PRONOM LE MOT'
57 AFFICHER 'QUI LUI FAIT SUITE DANS LE TEXTE, SANS TENIR COMPTE DE LA'
58 AFFICHER 'PONCTUATION MEME SI CE MOT EST CONSTITUE D"UNE SEULE LETTRE.'
59 AFFICHER 'S"IL EST RELIE PAR UNE APOSTROPHE, NE PAS TAPER CELLE-CI.'
60 AFFICHER[2/,'TAPE CO PUIS LA TOUCHE RUB-OUT.']
61 PAUSE;&AFTEX()
65 AFFICHER[/,'TAPE FIN LORSQUE TU AURAS ENTRE TOUS LES  PRONOMS.']
66 AFFICHER 'TAPE TEXTE SI TU VEUX REAFFICHER LE TEXTE.'
67 AFFICHER[2/,'N"OUBLIE PAS DE TERMINER CHAQUE REPONSE PAR RUB-OUT !!!']
68 AFFICHER[/,54'-',3/]
69 PRO_0;&NBPRO()
70 AFFICHER[/];ER_0;TZ_1;LIRE QUIZ;SI QUIZ='FIN' ALORS ALLER EN 81
71 X_0;SI QUIZ='TEXTE' ALORS DEBUT &AFTEX();ALLER EN 70 FIN
72 CHARGER PROCA,NE+2,NOM;PROCA_SCH(PROCA,6,LGR(PROCA)-5)
73 CATE_SCH(PROCA,1,'/',BX);SI QUIZ=CATE ALORS DEBUT PRO_PRO+1;ALLER EN 79 FIN
74 X_X+1
75 SI BX=LGR(PROCA) ET QUIZ#'FIN' ALORS &ENS();SI ER=1 ALORS ALLER EN 70
76 SI BX<LGR(PROCA) ALORS ALLER EN 78
77 SI X=0 ALORS ALLER EN 73
78 PROCA_SCH(PROCA,LGR(CATE)+2,LGR(PROCA)-LGR(CATE)+1);ALLER EN 73
79 TZ_1;BX_0;SI QUIZ#'FIN' ALORS ALLER EN 70
81 SI PRO<ZPRO-10 ALORS AFFICHER 'VEUX-TU RECONSULTER LE TABLEAU ?';LIRE QUIZ
82 SI QUIZ='OUI' ALORS &TABC();SI PRO>ZPRO-11 ALORS ALLER EN 85
83 AFFICHER ' VEUX-TU RAJOUTER DES PRONOMS OUBLIES ?';LIRE QUIZ;I_1
84 SI QUIZ='OUI' ALORS ALLER EN 70
86 AFFICHER[2/,'VOICI LA LISTE COMPLETE :']
87 CHARGER PROCA,NE+2,NOM;AFFICHER PROCA
88 SI NEN>1 ALORS DEBUT CHARGER PROCA,NE+3,NOM;AFFICHER PROCA FIN
90 NOT_PRO/(ZPRO/20)
92 AFFICHER[3/,'...ET VOICI TA NOTE : ',U,'/20']NOT
95 TERMINER
100 PROCEDURE &AFTEX();&NEN()
101 CHARGER E6,NE+1,NOM;TITRE_SCH(E6,1,'/');OTEUR_SCH(E6,LGR(TITRE)+2,'/')
102 C_40-LGR(TITRE)/2;AFFICHER[/,*X,U,/]C,TITRE
103 FAIRE 115 POUR I_1 JUSQUA NE
104 CHARGER TEX,I,NOM;SI I>1 ALORS TEX_TEXT!' '!TEX;&SUIT()
105 L_79;L0_LGR(TEX)
106 PL_SCH(TEX,1,L)
108 SI SCH(PL,L,1)=' ' ALORS ALLER EN 109 SINON L_L-1;ALLER EN 106
109 SI I<NE ET LGR(TEX)-L<80 ALORS DEBUT TEXT_TEX;ALLER EN 115 FIN
110 AFFICHER PL;TEX_SCH(TEX,L+1,LGR(TEX)-L)
111 SI I=NE ET LGR(TEX)<80 ALORS DEBUT AFFICHER TEX;ALLER EN 115 FIN
112 ALLER EN 105
115* DERNIERE LIGNE DE LA BOUCLE
116 AFFICHER[2/,60X,U]OTEUR
117 RETOUR
120 PROCEDURE &TABC()
123 AFFICHER[2/]
125 AFFICHER 'NOMME LE NOM DE LA CATEGORIE DE PRONOMS QUE TU VEUX CONSULTER'
126 AFFICHER[/,5X,'PRONOMS '];LIRE QUIZ
128 SI QUIZ='INDEFINIS' ALORS DEBUT CHARGER CAT,2,'PRONO';AFFICHER CAT FIN
129 SI QUIZ='RELATIFS' ALORS DEBUT CHARGER CAT,3,'PRONO';AFFICHER CAT FIN
130 SI QUIZ='DEMONSTRATIFS' ALORS DEBUT CHARGER CAT,4,'PRONO';AFFICHER CAT FIN
131 SI QUIZ#'DEMONSTRATIFS-RELATIFS' ALORS ALLER EN 133
132 CHARGER CAT,5,'PRONO';AFFICHER CAT;ALLER EN 134
133 SI QUIZ='DEMONSTRATIFS RELATIFS' ALORS ALLER EN 132
134 SI QUIZ='PERSONNELS' ALORS DEBUT CHARGER CAT,6,'PRONO';AFFICHER CAT FIN
135 SI QUIZ='REFLECHIS' ALORS DEBUT CHARGER CAT,7,'PRONO';AFFICHER CAT FIN
136 SI QUIZ='POSSESSIFS' ALORS DEBUT CHARGER CAT,8,'PRONO';AFFICHER CAT FIN
137 SI QUIZ='INTERROGATIFS' ALORS DEBUT CHARGER CAT,9,'PRONO';AFFICHER CAT FIN
138 AFFICHER[/,'VEUX-TU CONSULTER UN AUTRE TABLEAU ?'];LIRE QUIZ
140 SI QUIZ='OUI' ALORS ALLER EN 123 SINON RETOUR
150 PROCEDURE &NEN()
152 CHARGER E6,1,NOM
154 QUIZ_SCH(E6,1,'/')
156 NE_CNB(E6,1)
158 RETOUR
160 PROCEDURE &SUIT()
162 SI I=1 ALORS TEX_SCH(TEX,3,LGR(TEX)-2)
164 RETOUR
170 PROCEDURE &NBPRO()
172 CHARGER QUIZ,NE+2,NOM
174 PROCA_SCH(QUIZ,1,'/')
176 NEN_CNB(PROCA,1)
178 CAT_SCH(QUIZ,3,'/')
180 ZPRO_CNB(CAT,1);RETOUR
200 PROCEDURE &ENS()
202 SI NEN#1 ET TZ#NEN ALORS ALLER EN 204
203 RETOUR
204 CHARGER PROCA,NE+2+TZ,NOM;TZ_TZ+1;X_0
205 CATE_''
206 RETOUR