parser.peg

Program            <- CompoundCommand* Eof { PUSH_OPCODE(OPCODE_TERM); }

CompoundCommand   <- List
                   / IfStatement
                   / WhileLoop
                   / ForLoop
                   / CaseStatement
                   / FunctionDefinition
                   / VariableAssignment
                   / Comment
                   / TestExpr

List		   <- Pipeline ( _ "&&" _ Pipeline )* 
			{ PUSH_STACK_OPCODE(OPCODE_LIST_ANDIF); }
		   /  Pipeline ( _ "||" _ Pipeline )*
		   	{ PUSH_STACK_OPCODE(OPCODE_LIST_ANDOR); }

Pipeline	   <- Banged? _ SimpleCommand _ (  _ "|" _ SimpleCommand )*
				{ PUSH_OPCODE(OPCODE_PIPELINE); }


Banged             <- "!"		{ PUSH_OPCODE(OPCODE_BANGED); }

SimpleCommand      <- Word ( _ Word )* Redirections? 
			{ PUSH_OPCODE(OPCODE_SIMPLE_CMD); }

Redirections       <- Redirection ( _ Redirection )*

Redirection        <- InputRedirection
                  / OutputRedirection
                  / AppendOutputRedirection
                  / DuplicateOutputRedirection
                  / DuplicateInputRedirection
                  / HereDocument
                  / HereString

InputRedirection   <- FD? "<" Word	  { PUSH_OPCODE(OPCODE_INPUT_REDIR); }
OutputRedirection  <- FD? ">" Word	  { PUSH_OPCODE(OPCODE_OUTPUT_REDIR):}
AppendOutputRedirection <- FD? ">>" Word  { PUSH_OPCODE(OPCODE_APPEND_REDIR);}
DuplicateOutputRedirection <- FD? "&>" Word { PUSH_OPCODE(OPCODE_DUPOUT_REDIR);}
DuplicateInputRedirection <- FD "<&" Word   { PUSH_OPCODE(OPCODE_DUPIN_REDIR);}
HereDocument      <- FD? "<<" Delimiter	    { PUSH_OPCODE(OPCODE_HERE_DOC); }
HereString        <- FD? "<<<" Word	    { PUSH_OPCODE(OPCODE_HERE_STR); }

Word               <- String
                  / QuotedString
                  / BacktickExpansion
		  / TildeExpansion
                  / Substitution
		  / OrdinaryWord

SpecialParam     <- "$" < [!@#$%^&*-+~] > { PUSH_SPECIAL_PARAM(yytext[0]); }

PosParam	 <- "$" < [0-9]+ >  { PUSH_POS_PARAM(&yytext[0], yyleng); }

QuotedString       <- "'" CharSeqLiteral "'"

String             <- '"' ( CharSeqLiteral / Substitution )* '"'

BacktickExpansion  <- '`' ( CharSeqLiteral / Substitution / CompoundCommand )* '`'

Substitution       <- VariableSubstitution 
                  / CommandSubstitution 
                  / ArithmeticSubstitution
		  / TildeExpansion

TildeExpansion    <- "~" ( "/" OrdinaryWord )* { PUSH_OPCODE(OPCODE_TILDE_EXPN); }

VariableSubstitution <- "$" (Name / ComplexVariable) 
				{ PUSH_OPCODE(OPCODE_VAR_SUB); }

ComplexVariable    <- Name ComplexDelim? ( Alternative
                          / RemoveSmallestSuffix 
                          / RemoveLargestSuffix 
                          / RemoveSmallestPrefix 
                          / RemoveLargestPrefix 
                          / ReplaceFirst 
                          / ReplaceAll	
                        )?

ComplexDelim       <- ":" { PUSH_OPCODE(OPCODE_DELIM_COLON); }

Alternative        <- "=" Pattern { PUSH_OPCODE(OPCODE_ALT_EQUALS); }
                  / "+" Pattern { PUSH_OPCODE(OPCODE_ALT_PLUS); }
                  / "-" Pattern { PUSH_OPCODE(OPCODE_ALT_DASH); }
                  / "?" Pattern { PUSH_OPCODE(OPCODE_ALT_QMARK); }

RemoveSmallestSuffix <- "%" Pattern { PUSH_OPCODE(OPCODE_RM_SMALLEST_SFX); }
RemoveLargestSuffix <- "%%" Pattern { PUSH_OPCODE(OPCODE_RM_LARGEST_SFX); }
RemoveSmallestPrefix <- "#" Pattern { PUSH_OPCODE(OPCODE_RM_SMALLEST_PFX); }
RemoveLargestPrefix <- "##" Pattern { PUSH_OPCODE(OPCODE_RM_LARGEST_PFX); }
ReplaceFirst       <- "/" Pattern "/" Replacement
			{ PUSH_OPCODE(OPCODE_REPLACE_FIRST); }
ReplaceAll         <- "//" Pattern "/" Replacement
			{ PUSH_OPCODE(OPCODE_REPLACE_ALL); }

CommandSubstitution <- "$(" CompoundCommand ")"
			{ PUSH_OPCODE(OPCODE_SUB_SHELL); }
ArithmeticSubstitution <- "$((" ArithmeticExpression "))" 
				{ PUSH_OPCODE(OPCODE_SUB_EXPR); }

ArithmeticExpression <- Term (Addition / Subtraction Term)*
Addition           <- "+" Term	{ PUSH_OPCODE(OPCODE_ARITH_ADD); }
Subtraction        <- "-" Term	{ PUSH_OPCODE(OPCODE_ARITH_SUB); }

Term               <- Factor (Multiplication / Division Factor)*
Multiplication     <- "*" Factor { PUSH_OPCODE(OPCODE_ARITH_MUL); }
Division           <- "/" Factor { PUSH_OPCODE(OPCODE_ARITH_DIV); }

Factor             <- FD
                  / Substitution

Pattern            <- OrdinaryWord	{ PUSH_OPCODE(OPCODE_PATTERN); }
Replacement        <- OrdinaryWord	{ PUSH_OPCODE(OPCODE_REPLACEMENT); }


FD                <- < [0-9]+ >  { PUSH_NUMBER(&yytext[0], yyleng); }
Delimiter         <- String	 { PUSH_OPCODE(OPCODE_DELIMITER); }

IfStatement       <- IfPrefix __ CompoundCommand* ElifStatement* ElseStatement? "fi"
				{ PUSH_OPCODE(OPCODE_IF_END); }

ElseStatement     <- ElsePrefix CompoundCommand* { PUSH_OPCODE(OPCODE_ELSE_END); }

ElifStatement     <- ElifPrefix CompoundCommand* { PUSH_OPCODE(OPCODE_ELIF_END); }

ElsePrefix        <- "else" 		 { PUSH_OPCODE(OPCODE_ELSE_BEGIN); }

ElifPrefix        <- "elif" _ List __ "then" { PUSH_OPCODE(OPCODE_ELIF_BEGIN); }

IfPrefix          <- "if" _ List __ "then" { PUSH_OPCODE(OPCODE_IF_BEGIN); }

WhileLoop         <- WhileLoopPrefix __ CompoundCommand __ "done"
			{ PUSH_OPCODE(OPCODE_WHILE_END); }

WhileLoopPrefix   <- "while" _ List __ "do"	{ PUSH_OPCODE(OPCODE_WHILE_BEGIN); }

ForLoop           <- ForLoopPrefix __ WordList __ "do" __ CompoundCommand __ "done"
			{ PUSH_OPCODE(OPCODE_FOR_END); }

ForLoopPrefix     <- "for" _ Name _ "in"	{ PUSH_OPCODE(OPCODE_FOR_BEGIN); }

WordList          <- Word _ ( ";" Word )* { PUSH_OPCODE(OPCODE_WORD_LIST_END); }

CaseStatement     <- CasePrefix __ CasePatternMultiple  __ "esac" { PUSH_OPCODE(OPCODE_CASE_END); }

CasePrefix        <- "case" _ Word  _ "in"	{ PUSH_OPCODE(OPCODE_CASE_BEGIN); }

CasePatternMultiple <- CasePatternSingle ( __ ";;" __ CasePatternSingle )*

CasePatternSingle   <- PatternList ")" __ CompoundCommand __ { PUSH_OPCODE(OPCODE_CASE_ITEM;); }

PatternList       <- OrdinaryWord ( _ "|" _ OrdinaryWord )* { PUSH_OPCODE(OPCODE_CASE_PATTERN); }

FunctionDefinition <- _ Name _ "()" __ "{" CompoundCommand* "}" 
			{ PUSH_OPCODE(OPCODE_STMT_FUNCTION); }

VariableAssignment <- Name "=" Word { PUSH_OPCODE(OPCODE_STMT_ASSIGN); }

Comment           <- "#" AnyCharExceptNewline* "\n" { /* ignore */ }


TestExpr          <- "test" _ TestJunction
                  / "[" _ TestJunction _ "]"

TestJunction      <- TestTerm _ BinaryOperator _ TestTerm
		    { PUSH_OPCODE(STACK_TEST_TERM_BINARY); }
                  / TestTerm { PUSH_OPCODE(OPCODE_TEST_TERM_UNARY); }

TestTerm          <- NormalTestTerm	     { PUSH_OPCODE(OPCODE_TEST_TERM_NORMAL); }
                  / NegatedTestTerm 	     { PUSH_OPCODE(OPCODE_TEST_TERM_NEGATE); }

NegatedTestTerm   <- "!" _ NormalTestTerm

NormalTestTerm    <- UnaryOperator Word	     

UnaryOperator     <- "-b"  { PUSH_OPCODE(OPCODE_TEST_IS_BLOCK); }
                  / "-c"   { PUSH_OPCODE(OPCODE_TEST_IS_CHAR); }
                  / "-d"   { PUSH_OPCODE(OPCODE_TEST_IS_DIRECTORY); } 
                  / "-e"   { PUSH_OPCODE(OPCODE_TEST_EXISTS); }
                  / "-f"   { PUSH_OPCODE(OPCODE_TEST_IS_REGULAR); }
                  / "-g"   { PUSH_OPCODE(OPCODE_TEST_IS_GROUPID_SET); }
                  / "-h"   { PUSH_OPCODE(OPCODE_TEST_IS_SYMLINK); }
                  / "-k"   { PUSH_OPCODE(OPCODE_TEST_IS_STICKY_SET); }
                  / "-p"   { PUSH_OPCODE(OPCODE_TEST_IS_NAMED_PIPE); }
                  / "-r"   { PUSH_OPCODE(OPCODE_TEST_IS_READABLE); }
                  / "-s"   { PUSH_OPCODE(OPCODE_TEST_IS_LARGER_ZERO); }
                  / "-t"   { PUSH_OPCODE(OPCODE_TEST_IS_TERMINAL);  }
                  / "-u"   { PUSH_OPCODE(OPCODE_TEST_IS_USERID_SET); }
                  / "-w"   { PUSH_OPCODE(OPCODE_TEST_IS_WRITABLE); } 
                  / "-x"   { PUSH_OPCODE(OPCODE_TEST_IS_EXECUTABLE); }
                  / "-z"   { PUSH_OPCODE(OPCODE_TEST_STR_EMPTY); }

BinaryOperator    <- "-eq" { PUSH_OPCODE(OPCODE_TEST_EQUALS); }
                  / "-ne" { PUSH_OPCODE(OPCODE_TEST_UNEQUALS); }
                  / "-lt" { PUSH_OPCODE(OPCODE_TEST_LESSER); }
                  / "-le" { PUSH_OPCODE(OPCODE_TEST_LESSER_EQUALS); }
                  / "-gt" { PUSH_OPCODE(OPCODE_TEST_GREATER);  }
                  / "-ge" { PUSH_OPCODE(OPCODE_TEST_GREATER_EQUALS); } 


CharSeqLiteral	   <- < AnyCharExceptNewline* > { PUSH_WORD(&yytext[0], yyleng); }

Name               <- < [a-zA-Z_][a-zA-Z_0-9]* > { PUSH_NAME(&yytext[0], yyleng); }
OrdinaryWord 	   <- < ( !( [|<>![\]\n#$&*(){};?"'\\] ) . )+ > { PUSH_WORD(&yytext[0], yyleng); }


AnyCharExceptNewline <- ![\n\r]
Eof               <- !.				

_                 <- [ \t]*
__                <- [ \t\r\n]*