build.gradle

buildscript {
    ext.kotlin_version = '1.4.10'
    ext.kotlinx_coroutines_version = '1.3.9'

    repositories {
        mavenLocal()
        jcenter()
        mavenCentral()
        google()
        maven { url = 'https://oss.sonatype.org/content/repositories/snapshots/' }
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:4.0.2'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
        classpath 'com.google.gms:google-services:4.3.4'
        classpath 'com.cyphercove.icondivvy:icondivvy:0.2'
    }
}

apply plugin: "com.cyphercove.icondivvy"

iconDivvy {
    jobs {
        legacyIcon {
            stagingDir = "resource staging/launcher-legacy"
            resourceDir = "android/res"
            resourceType = "mipmap"
            sizeDip = 48
        }
        adaptiveIcon {
            stagingDir = "resource staging/launcher-adaptive"
            resourceDir = "android/res"
            resourceType = "drawable"
            sizeDip = 108
        }
        banners {
            stagingDir = "resource staging/preference-banner"
            resourceDir = "android/res"
            resourceType = "drawable"
            sizeDip = 300
        }
    }
}

allprojects {
    apply plugin: "eclipse"
    apply plugin: "idea"

    ext {
        appName = 'Double Helix'
        gdxVersion = '1.9.11'
        gdxKtxVersion = '1.9.11-b1'
        coveToolsVersion = '1.2.4'
        gdxTweenVersion = '0.1.4'
        coveprefsVersion = '2.0.2'
        appCompatVersion = '1.0.2'
        preferenceVersion = '1.1.0-rc01'
    }

    repositories {
        mavenLocal()
        jcenter()
        maven {
            url = "https://maven.google.com"
        }
        mavenCentral()
        maven { url = "https://jitpack.io" }
        maven { url = "https://oss.sonatype.org/content/repositories/snapshots/" }
        maven { url = "https://oss.sonatype.org/content/repositories/releases/" }
    }
}

project(":desktop") {
    apply plugin: "java"

    dependencies {
        implementation project(":core")
        implementation "com.badlogicgames.gdx:gdx-backend-lwjgl3:$gdxVersion"
        implementation "com.badlogicgames.gdx:gdx-platform:$gdxVersion:natives-desktop"
    }
}

project(":android") {
    apply plugin: "com.android.application"
    apply plugin: 'kotlin-android'
    apply plugin: 'kotlin-android-extensions'

    configurations { natives }

    dependencies {
        implementation"org.jetbrains.kotlin:kotlin-stdlib-jdk7:$kotlin_version"
        implementation "org.jetbrains.kotlinx:kotlinx-coroutines-android:$kotlinx_coroutines_version"

        api project(":core")
        implementation "com.badlogicgames.gdx:gdx-backend-android:$gdxVersion"
        implementation "com.cyphercove.covetools:covetools-android:$coveToolsVersion"
        implementation "com.cyphercove.coveprefs:coveprefs:$coveprefsVersion"
        implementation "com.cyphercove.gdxtween:gdxtween:$gdxTweenVersion"
        natives "com.badlogicgames.gdx:gdx-platform:$gdxVersion:natives-armeabi"
        natives "com.badlogicgames.gdx:gdx-platform:$gdxVersion:natives-armeabi-v7a"
        natives "com.badlogicgames.gdx:gdx-platform:$gdxVersion:natives-arm64-v8a"
        natives "com.badlogicgames.gdx:gdx-platform:$gdxVersion:natives-x86"
        natives "com.badlogicgames.gdx:gdx-platform:$gdxVersion:natives-x86_64"

        implementation "androidx.appcompat:appcompat:$appCompatVersion"
        implementation 'androidx.core:core-ktx:1.3.2'
        implementation "androidx.fragment:fragment-ktx:1.2.5"
        implementation "androidx.preference:preference:$preferenceVersion"
        implementation 'androidx.lifecycle:lifecycle-extensions:2.2.0'
        implementation 'com.jakewharton.timber:timber:4.7.1'
    }
}

project(":core") {
    apply plugin: "java-library"

    dependencies {
        api "com.badlogicgames.gdx:gdx:$gdxVersion"
        api ("com.cyphercove.covetools:covetools:$coveToolsVersion"){ changing = true }
        implementation ("com.cyphercove.gdxtween:gdxtween:$gdxTweenVersion"){ changing = true }
    }
}

tasks.eclipse.doLast {
    delete ".project"
}