build.gradle

buildscript {
    repositories {
        maven {
            url = 'https://plugins.gradle.org/m2'
        }

        dependencies {
            classpath 'com.github.jengelman.gradle.plugins:shadow:5.1.0'
            classpath 'gradle.plugin.net.minecrell:licenser:0.4.1'
            classpath 'org.sonarsource.scanner.gradle:sonarqube-gradle-plugin:2.7'
        }
    }
}

subprojects {
    apply plugin: 'java'
    apply plugin: 'idea'

    apply plugin: 'com.github.johnrengelman.shadow'
    apply plugin: 'net.minecrell.licenser'
    apply plugin: 'org.sonarqube'

    group 'me.piggypiglet'
    version '1.8.41'
    sourceCompatibility = 1.8

    repositories {
        mavenCentral()
        maven {
            url = 'https://repo.piggypiglet.me/repository/maven-releases/'

            content {
                includeGroup 'me.piggypiglet'
            }
        }
    }

    dependencies {
        testCompile 'junit:junit:4.12'
    }

    shadowJar {
        exclude 'META-INF/*.SF'
        exclude 'META-INF/*.DSA'
        exclude 'META-INF/*.RSA'
    }
    
    license {
        header = file("$rootDir/LICENSE.md")
        ext {
            year = 2020
        }
        include '**/*.java'
        exclude '**/minecraft/text/Text.java'
    }

    compileJava.options.encoding = 'UTF-8'

    task sourcesJar(type: Jar, dependsOn: classes) {
        archiveClassifier.set('sources')
        from sourceSets.main.allSource
    }

    task javadocJar(type: Jar, dependsOn: javadoc) {
        archiveClassifier.set('javadoc')
        from javadoc.destinationDir
    }

    artifacts {
        archives sourcesJar
        archives javadocJar
    }
}

def exportedProjects = [
        ":core",
        ":addons:console",
        ":addons:mysql",
        ":addons:logback",
        ":addons:http",
        ":addons:jars",
        ":bindings:minecraft:common",
        ":bindings:minecraft:bukkit",
        ":bindings:minecraft:sponge",
        ":bindings:minecraft:velocity",
        ":bindings:minecraft:bungeecord",
        ":bindings:minecraft:nukkit",
        ":bindings:discord:jda"
]

task allJavadoc(type: Javadoc) {
    source exportedProjects.collect {
        project(it).sourceSets.main.allJava
    }
    classpath = files(exportedProjects.collect {
        project(it).sourceSets.main.compileClasspath
    })
    destinationDir = file("${buildDir}/docs/javadoc")
}