properties.bat

:: This program is free software: you can redistribute it and/or modify it under the terms of the GNU General Public License as published by the Free Software Foundation, either version 3 of the License, or (at your option) any later version.
:: This program is distributed in the hope that it will be useful, but WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License for more details.
:: You should have received a copy of the GNU General Public License along with this program. If not, see http://www.gnu.org/licenses/.

:: Copyright 2023 Thqrn. Licensed under the GNU General Public License v3.0.

:: @froest on Discord
:: https://github.com/Thqrn/ffmpeg-scripts

@echo off
:: removing and making temp folder
rmdir %temp%\propertiesfinder /s /q > nul 2> nul
mkdir %temp%\propertiesfinder
set newtemp=%temp%\propertiesfinder
choice /n /m "Show total frame counts? (slower)"
cls
if %errorlevel% == 1 set showfc=y
if %errorlevel% == 2 set showfc=n
:: for each file used as an input, find its properties
for %%a in (%*) do (
    set inputvideo=%%a
    set inputviduserfriendly=%%~nxa
    call :findproperties
    echo -----------------------------------------------------------------------------------------------------------------------
)
:: deleting temp folder
rmdir %temp%\propertiesfinder /s /q
where /q ffplay || goto aftersound
if not exist "C:\Windows\Media\notify.wav" (goto aftersound) else ffplay "C:\Windows\Media\notify.wav" -volume 50 -autoexit -showmode 0 -loglevel quiet
:aftersound
pause
exit

:findproperties
:: reset variables
set "vformat="
set "aformat="
set "height="
set "width="
set "fpsvalue="
set "duration="
set "frames="
:: video format
ffprobe -v error -select_streams v:0 -show_entries stream=codec_name -of default=noprint_wrappers=1:nokey=1 -i %inputvideo% > %newtemp%\vformat.txt
set /p vformat=<%newtemp%\vformat.txt
if "%vformat%1" == "1" (set vformat=N/A) else set vformat=%vformat%
:: audio format
ffprobe -v error -select_streams a:0 -show_entries stream=codec_name -of default=noprint_wrappers=1:nokey=1 -i %inputvideo% > %newtemp%\aformat.txt
set /p aformat=<%newtemp%\aformat.txt
if "%aformat%1" == "1" (set aformat=N/A) else set aformat=%aformat%
:: width and height
ffprobe -v error -select_streams v:0 -show_entries stream=width -i %inputvideo% -of csv=p=0 > %newtemp%\width.txt
ffprobe -v error -select_streams v:0 -show_entries stream=height -i %inputvideo% -of csv=p=0 > %newtemp%\height.txt
set /p height=<%newtemp%\height.txt
set /p width=<%newtemp%\width.txt
set wbh=%width% by %height%
if "%width%1" == "1" set wbh=N/A
:: frames per second
ffprobe -v error -select_streams v:0 -show_entries stream=r_frame_rate -i %inputvideo% -of csv=p=0 > %newtemp%\fps.txt
set /p fpsvalue=<%newtemp%\fps.txt
if "%fpsvalue%1" == "1" (set fpsvalue=N/A) else set fpsvalue=%fpsvalue%
set fpsvalue=%fpsvalue:/1=%
:: duration
ffprobe -i %inputvideo% -show_entries format=duration -v quiet -of csv="p=0" > %newtemp%\fileduration.txt
set /p duration=<%newtemp%\fileduration.txt
if "%duration%1" == "1" (set duration=N/A) else set duration=%duration%
:: if frame count is off, skip and display now
if %showfc% == n goto noshowframecount
:: frame count
ffprobe -v error -select_streams v:0 -count_packets -show_entries stream=nb_read_packets -i %inputvideo% -of csv=p=0 > %newtemp%\frames.txt
set /p frames=<%newtemp%\frames.txt
if "%frames%1" == "1" (set frames=N/A) else set frames=%frames%
:: display file properties
echo  ^> %inputviduserfriendly%
echo    video format^| audio format^| resolution ^| frames per second ^| duration (in seconds)^| Frames
echo    %vformat% ^| %aformat% ^| %wbh% ^| %fpsvalue%^| %duration%^| %frames%
goto :eof

:noshowframecount
:: display file properties (excluding frame count)
echo  ^> %inputviduserfriendly%
echo    video format^| audio format^| resolution ^| frames per second ^| duration (in seconds)
echo    %vformat% ^| %aformat% ^| %wbh% ^| %fpsvalue%^| %duration%
goto :eof