Constraint validation doesn't seem to ensure that the validated value is of the particular type

[MaryamZi]

Description:
$title, may have to convert the value in the Java implementation.

Steps to reproduce:

import ballerina/constraint;
import ballerina/io;

type User record {|
    int id;
    @constraint:String {
        minLength: 2
    }
    string name;
|};

public function main() returns error? {
    json j = {
        "id": 1,
        "name": "Joy"
    };

    User|error user = constraint:validate(j);
    if user !is error {
        // validation was successful, `user` will be of type `User` here
        io:println(user is User); // expected true, prints false
        io:println(user === j); // expected false, prints true, value is still the original JSON object
    }
}

Affected Versions:
2201.3.2

[TharmiganK]

With the current implementation we only use the typedesc from the validate() function, to infer the constraint annotations. We could improve this behavior by converting the value to the contextually expected type(using CloneWithType.convert(type, value)), only when the type of the value is different from the contextually expected type. This should solve this issue.

The conversion will be done before the validation to avoid unnecessary validation of unmatched type and value.

With the above fix suggestion, we could expect the following output:

import ballerina/constraint;
import ballerina/io;

type User record {|
    int id;
    @constraint:String {
        minLength: 2
    }
    string name;
|};

public function main() returns error? {
    json j1 = {"id": 1, "name": "Joy"};
    // j1 will be cloned with User type
    User user1 = check constraint:validate(j1);
    io:println(user1 is User); // prints true
    io:println(user1 === j1); // prints false

    User user = {"id": 1, "name": "Joy"};
    // user will not be cloned
    user = check constraint:validate(user);
    io:println(user is User); // prints true

    // user will not be cloned 
    User validation = check constraint:validate(user);
    io:println(validation is User); // prints true
    io:println(validation === user); // prints true

    json j2 = {"id": 1, "username": "Joy"};
    User _ = check constraint:validate(j2); // Returns an error
}

[github-actions]

This issue is NOT closed with a proper Reason/ label. Make sure to add proper reason label before closing. Please add or leave a comment with the proper reason label now.

      - Reason/EngineeringMistake - The issue occurred due to a mistake made in the past.
      - Reason/Regression - The issue has introduced a regression.
      - Reason/MultipleComponentInteraction - Issue occured due to interactions in multiple components.
      - Reason/Complex - Issue occurred due to complex scenario.
      - Reason/Invalid - Issue is invalid.
      - Reason/Other - None of the above cases.