build.gradle

plugins {
    id 'org.beryx.runtime' version '1.11.4'
}

repositories {
    mavenCentral()
}

sourceCompatibility = 11
targetCompatibility = 11

def defaultEncoding = 'UTF-8'
[compileJava, compileTestJava]*.options*.encoding = defaultEncoding


application {
    mainClass = 'org.beryx.hello.Hello'
    applicationName = 'hello'
}

jar {
    manifest {
        attributes 'Implementation-Title': "hello",
                'Main-Class': 'org.beryx.hello.Hello'
    }
}

runtime {
    options = ['--strip-debug', '--compress', '2', '--no-header-files', '--no-man-pages']
    jpackage {
        // The environment variable BADASS_RUNTIME_JPACKAGE_HOME should point to a Java 16 installation.
        installerOptions += ['--resource-dir', "src/main/resources"]
        installerOptions += ['--verbose']
        // The next line is for test only. If you uncomment it, the build will fail, but you'll be able to see the resources used to package the application.
        // installerOptions += ['--temp', "build/tmpfiles"]
        if(org.gradle.internal.os.OperatingSystem.current().windows) {
            imageOptions += ['--win-console']
            installerOptions += ['--win-per-user-install', '--win-dir-chooser', '--win-menu', '--win-shortcut']
        }
    }
}