build.gradle.kts

plugins {
    id("net.minecraftforge.gradle") version "6.0+"
    id("org.spongepowered.mixin") version "0.7+"
}

version = "1.0.0"
group = "net.ctrlaltmilk"

java.toolchain.languageVersion = JavaLanguageVersion.of(17)

minecraft {
    mappings("official", "1.20.1")

    runs {
        all {
            property("terminal.jline", "true")

            property("mixin.env.remapRefMap", "true")
            property("mixin.env.refMapRemappingFile", "$projectDir/build/createSrgToMcp/output.srg")

            mods.create("handsoffmydata").sources(sourceSets.main.get())
        }

        register("client") {}
    }
}

mixin {
    config("handsoffmydata.mixins.json")
    add(sourceSets.main.get(), "handsoffmydata.refmap.json")
}

repositories {
    flatDir {
        dirs("libs")
    }
    maven("https://cursemaven.com/")
}

dependencies {
    minecraft("net.minecraftforge:forge:1.20.1-47.3.22")

    implementation(fg.deobf("libs:protection_pixel:1.1.3-forge-1.20.1"))
    implementation(fg.deobf("curse.maven:create-328085:5838779"))
    implementation(fg.deobf("curse.maven:curios-309927:6058834"))

    annotationProcessor("org.spongepowered:mixin:0.8.5:processor")
}

tasks {
    processResources {
        val props = mapOf(
                "version" to project.version
        )

        inputs.properties(props)

        filesMatching("META-INF/mods.toml") {
            expand(props)
        }

        exclude("*.kra") // Original Krita textures
    }
}