-
Notifications
You must be signed in to change notification settings - Fork 5
/
build.gradle.kts
146 lines (129 loc) · 3.62 KB
/
build.gradle.kts
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
import org.jetbrains.dokka.DokkaConfiguration
import org.jetbrains.dokka.gradle.DokkaTask
import org.owasp.dependencycheck.gradle.extension.DependencyCheckExtension
import java.net.URL
object Meta {
const val BASE_URL = "https://github.com/eu-digital-identity-wallet/eudi-lib-jvm-sdjwt-kt"
}
plugins {
base
`java-library`
`maven-publish`
signing
jacoco
alias(libs.plugins.dokka)
alias(libs.plugins.kotlin.jvm)
alias(libs.plugins.kotlin.plugin.serialization)
alias(libs.plugins.spotless)
alias(libs.plugins.sonarqube)
alias(libs.plugins.dependencycheck)
alias(libs.plugins.maven.publish)
alias(libs.plugins.kotlinx.knit)
}
repositories {
mavenCentral()
mavenLocal()
}
dependencies {
api(libs.kotlinx.serialization.json)
api(libs.nimbus.jose.jwt)
implementation(libs.kotlinx.coroutines.core)
api(libs.ktor.client.core)
api(libs.ktor.client.content.negotiation)
api(libs.ktor.client.serialization)
api(libs.ktor.serialization.kotlinx.json)
testImplementation(kotlin("test"))
testImplementation(libs.tink)
testImplementation(libs.kotlinx.coroutines.test)
testImplementation(libs.ktor.client.mock)
}
java {
sourceCompatibility = JavaVersion.toVersion(libs.versions.java.get())
}
kotlin {
jvmToolchain {
languageVersion.set(JavaLanguageVersion.of(libs.versions.java.get()))
compilerOptions {
optIn = listOf("kotlin.io.encoding.ExperimentalEncodingApi")
}
}
}
knit {
rootDir = project.rootDir
files = fileTree(project.rootDir) {
include("docs/examples/**/*.md")
include("README.md")
}
defaultLineSeparator = "\n"
}
spotless {
val ktlintVersion = libs.versions.ktlintVersion.get()
kotlin {
ktlint(ktlintVersion)
licenseHeaderFile("FileHeader.txt")
}
kotlinGradle {
ktlint(ktlintVersion)
}
}
testing {
suites {
val test by getting(JvmTestSuite::class) {
useJUnitJupiter()
}
}
}
tasks.jacocoTestReport {
reports {
xml.required.set(true)
}
}
tasks.jar {
manifest {
attributes(
mapOf(
"Implementation-Title" to project.name,
"Implementation-Version" to project.version,
),
)
}
}
tasks.withType<DokkaTask>().configureEach {
dokkaSourceSets {
named("main") {
// used as project name in the header
moduleName.set("EUDI SD-JWT")
// contains descriptions for the module and the packages
includes.from("Module.md")
documentedVisibilities.set(
setOf(
DokkaConfiguration.Visibility.PUBLIC,
DokkaConfiguration.Visibility.PROTECTED,
),
)
val remoteSourceUrl = System.getenv()["GIT_REF_NAME"]?.let { URL("${Meta.BASE_URL}/tree/$it/src") }
remoteSourceUrl
?.let {
sourceLink {
localDirectory.set(projectDir.resolve("src"))
remoteUrl.set(it)
remoteLineSuffix.set("#L")
}
}
}
}
}
mavenPublishing {
pom {
ciManagement {
system = "github"
url = "${Meta.BASE_URL}/actions"
}
}
}
val nvdApiKey: String? = System.getenv("NVD_API_KEY") ?: properties["nvdApiKey"]?.toString()
val dependencyCheckExtension = extensions.findByType(DependencyCheckExtension::class.java)
dependencyCheckExtension?.apply {
formats = mutableListOf("XML", "HTML")
nvd.apiKey = nvdApiKey ?: ""
}