main.tf

locals {
  environment = "${terraform.workspace == "default" ? "test" : terraform.workspace}"
}

resource "azurerm_resource_group" "ansible_management" {
  name     = "${var.name_prefix}-ansible-mgmt-${local.environment}-rg"
  location = "${var.location}"

  tags = {
    Environment = "${local.environment}"
    ManagedBy   = "TF"
  }
}

data "azurerm_subnet" "existing_subnet" {
  name                 = "${var.existing_subnet_name}"
  virtual_network_name = "${var.existing_vnet_name}"
  resource_group_name  = "${var.existing_rg_for_vnet}"
}

resource "azurerm_public_ip" "ansible_mgmt_public_ip" {
  name                         = "${var.name_prefix}-ansible-mgmt-pip-${local.environment}"
  resource_group_name          = "${azurerm_resource_group.ansible_management.name}"
  public_ip_address_allocation = "static"
  location                     = "${var.location}"

  tags = {
    Environment = "${local.environment}"
    ManagedBy   = "TF"
  }
}

resource "azurerm_network_interface" "ansible_management" {
  name                = "${var.name_prefix}-ansible-mgmt-${local.environment}"
  resource_group_name = "${azurerm_resource_group.ansible_management.name}"
  location            = "${var.location}"

  ip_configuration {
    name = "${var.name_prefix}-ansible-ipconfig-${local.environment}"

    subnet_id                     = "${data.azurerm_subnet.existing_subnet.id}"
    private_ip_address_allocation = "dynamic"
    public_ip_address_id          = "${azurerm_public_ip.ansible_mgmt_public_ip.id}"
  }

  tags = {
    Environment = "${local.environment}"
    ManagedBy   = "TF"
  }
}

resource "azurerm_virtual_machine" "ansible_management_node" {
  name                  = "${var.name_prefix}-ansible-mgmt-${local.environment}"
  resource_group_name   = "${azurerm_resource_group.ansible_management.name}"
  location              = "${var.location}"
  network_interface_ids = ["${azurerm_network_interface.ansible_management.id}"]
  vm_size               = "${var.vm_size}"

  storage_image_reference {
    publisher = "Canonical"
    offer     = "UbuntuServer"
    sku       = "16.04-LTS"
    version   = "latest"
  }

  storage_os_disk {
    name          = "${var.name_prefix}-ansible-mgmt-osdisk-${local.environment}"
    caching       = "ReadWrite"
    create_option = "FromImage"
  }

  os_profile {
    computer_name  = "${var.name_prefix}-ansible-${local.environment}"
    admin_username = "${var.vm_username}"
    admin_password = "${var.vm_password}"
  }

  os_profile_linux_config {
    disable_password_authentication = false
  }

  tags = {
    Environment = "${local.environment}"
    ManagedBy   = "TF"
    role        = "ansible-management"
    ssh_ip      = "${azurerm_public_ip.ansible_mgmt_public_ip.ip_address}"
    ssh_user    = "${var.vm_username}"
    Name        = "${var.name_prefix}-ansible-${local.environment}"
  }
}