Jenkinsfile

def buildVersion
def boards_to_build = ["WiPy", "LoPy", "SiPy", "GPy", "FiPy", "LoPy4"]
def boards_to_test = ["Pycom_Expansion3_Py00ec5f", "Pycom_Expansion3_Py9f8bf5"]

node {
    // get pycom-esp-idf source
    stage('Checkout') {
        checkout scm
        sh 'rm -rf esp-idf'
        sh 'git clone --recursive -b master https://github.com/pycom/pycom-esp-idf.git esp-idf'
        sh 'git -C esp-idf checkout 4eab4e1b0e47c73b858c6b29d357f3d30a69c074'
        sh 'git -C esp-idf submodule update'
    }
    
    PYCOM_VERSION=get_version()
    GIT_TAG = sh (script: 'git rev-parse --short HEAD', returnStdout: true).trim()

    stage('mpy-cross') {
        // build the cross compiler first
        sh 'git tag -fa v1.8.6-849-' + GIT_TAG + ' -m \\"v1.8.6-849-' + GIT_TAG + '''\\";
          cd mpy-cross;
          make clean;
          make all'''
    }

    for (board in boards_to_build) {
        stage(board) {
            def parallelSteps = [:]
            parallelSteps[board] = boardBuild(board)
            parallel parallelSteps
        }
    }

    stash includes: '**/*.bin', name: 'binary'
    stash includes: 'tests/**', name: 'tests'
    stash includes: 'esp-idf/components/esptool_py/**', name: 'esp-idfTools'
    stash includes: 'tools/**', name: 'tools'
    stash includes: 'esp32/tools/**', name: 'esp32Tools'
}

stage ('Flash') {
    def parallelFlash = [:]
    for (board in boards_to_test) {
        parallelFlash[board] = flashBuild(board)
    }
    parallel parallelFlash
}

stage ('Test'){
    def parallelTests = [:]
    for (board in boards_to_test) {
        parallelTests[board] = testBuild(board)
    }
    parallel parallelTests
}


def boardBuild(name) {
    def name_u = name.toUpperCase()
    def name_short = name_u.split('_')[0]
    def app_bin = name.toLowerCase() + '.bin'
    return {
            release_dir = "${JENKINS_HOME}/release/${JOB_NAME}/" + PYCOM_VERSION + "/" + GIT_TAG + "/"
        sh '''export PATH=$PATH:/opt/xtensa-esp32-elf/bin;
        export IDF_PATH=${WORKSPACE}/esp-idf;
        cd esp32;
        make clean BOARD=''' + name_short

        sh '''export PATH=$PATH:/opt/xtensa-esp32-elf/bin;
        export IDF_PATH=${WORKSPACE}/esp-idf;
        cd esp32;
        make TARGET=boot -j2 BOARD=''' + name_short

        sh '''export PATH=$PATH:/opt/xtensa-esp32-elf/bin;
        export IDF_PATH=${WORKSPACE}/esp-idf;
        cd esp32;
        make TARGET=app -j2 BOARD=''' + name_short

        sh '''cd esp32/build/'''+ name_u +'''/release;
        mkdir -p firmware_package;
        mkdir -p '''+ release_dir + ''';
        cd firmware_package;
        cp ../bootloader/bootloader.bin .;
        mv ../application.elf ''' + release_dir + name + "-" + PYCOM_VERSION + '''-application.elf;
        cp ../''' + app_bin + ''' appimg.bin;
        cp ../lib/partitions.bin .;
        cp ../../../../boards/''' + name_short + '''/''' + name_u + '''/script .;
        cp ../''' + app_bin + ''' .;
        tar -cvzf ''' + release_dir + name + "-" + PYCOM_VERSION + '''.tar.gz  appimg.bin  bootloader.bin   partitions.bin   script ''' + app_bin
    }
}

def flashBuild(short_name) {
  return {
    String device_name = get_device_name(short_name)
    String board_name_u = get_firmware_name(short_name)
    node(get_remote_name(short_name)) {
      sh 'rm -rf *'
      unstash 'binary'
      unstash 'esp-idfTools'
      unstash 'esp32Tools'
      unstash 'tests'
      unstash 'tools'
      sh 'python esp32/tools/pypic.py --port ' + device_name +' --enter'
      sh 'esp-idf/components/esptool_py/esptool/esptool.py --chip esp32 --port ' + device_name +' --baud 921600 --before no_reset --after no_reset erase_flash'
      sh 'python esp32/tools/pypic.py --port ' + device_name +' --enter'
      sh 'esp-idf/components/esptool_py/esptool/esptool.py --chip esp32 --port ' + device_name +' --baud 921600 --before no_reset --after no_reset write_flash -pz --flash_mode dio --flash_freq 80m --flash_size detect 0x1000 esp32/build/'+ board_name_u +'/release/bootloader/bootloader.bin 0x8000 esp32/build/'+ board_name_u +'/release/lib/partitions.bin 0x10000 esp32/build/'+ board_name_u +'/release/' + board_name_u.toLowerCase() + '.bin'
      sh 'python esp32/tools/pypic.py --port ' + device_name +' --exit'
    }
  }
}

def testBuild(short_name) {
  return {
    String device_name = get_device_name(short_name)
    String board_name_u = get_firmware_name(short_name)
    node(get_remote_name(short_name)) {
        sleep(5) //Delay to skip all bootlog
        dir('tests') {
            timeout(30) {
                // As some tests are randomly failing... enforce script always returns 0 (OK)
                    sh './run-tests --target=esp32-' + board_name_u + ' --device ' + device_name + ' || exit 0'
                }
            }
            sh 'python esp32/tools/pypic.py --port ' + device_name +' --enter'
            sh 'python esp32/tools/pypic.py --port ' + device_name +' --exit'
    }
  }
}

def get_version() {
    def matcher = readFile('esp32/pycom_version.h') =~ 'SW_VERSION_NUMBER (.+)'
    matcher ? matcher[0][1].trim().replace('"','') : null
}

def get_firmware_name(short_name) {
  node {
    def node_info = sh (script: 'cat ${JENKINS_HOME}/pycom-ic.conf || exit 0', returnStdout: true).trim()
    def matcher = node_info =~ short_name + ':(.+):.*'
    matcher ? matcher[0][1] : "WIPY"
  }
}

def get_remote_name(short_name) {
  node {
    def node_info = sh (script: 'cat ${JENKINS_HOME}/pycom-ic.conf || exit 0', returnStdout: true).trim()
    def matcher = node_info =~ short_name + ':.*:(.+)'
    matcher ? matcher[0][1] : "RPI3"
  }
}

def get_device_name(short_name) {
    return "/dev/serial/by-id/usb-" +  short_name + "-if00"   
}