build.gradle

buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath "com.jfrog.bintray.gradle:gradle-bintray-plugin:0.3"
        classpath "com.github.townsfolk:gradle-release:1.2"
    }
}

apply plugin: "java"
apply plugin: "groovy"
apply plugin: "idea"
apply plugin: "maven-publish"

repositories {
    jcenter()
}

dependencies {
    compile "org.apache.jclouds:jclouds-blobstore:1.7.2"
    compile "org.mongodb:mongo-java-driver:2.12.1"
    testCompile "org.codehaus.groovy:groovy-all:2.3.0"
    testCompile "org.spockframework:spock-core:0.7-groovy-2.0"
}

sourceCompatibility = "1.7"

group = "com.commercehub.jclouds"

task sourceJar(type: Jar) {
    from sourceSets.main.allJava
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = "javadoc"
    from javadoc.destinationDir
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java
            artifact sourceJar {
                classifier "sources"
            }
            artifact javadocJar {
                classifier "javadoc"
            }
        }
    }
}

apply plugin: "bintray"
apply plugin: "release"

bintray {
    user = project.hasProperty("bintrayUserName") ? bintrayUserName : null
    key = project.hasProperty("bintrayApiKey") ? bintrayApiKey : null
    publications = ["mavenJava"]
    pkg {
        repo = "main"
        userOrg = "commercehub-oss"
        name = "jclouds-gridfs-blobstore"
        desc = "A JClouds BlobStore provider backed by MongoDB's GridFS"
        licenses = ['Apache-2.0']
        labels = ["mongodb", "jclouds", "gridfs"]
    }
}
bintrayUpload.dependsOn build, sourceJar, javadocJar

createReleaseTag.dependsOn bintrayUpload