forked from NREL/EnergyPlus
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathCMakeLists.txt
339 lines (269 loc) · 12.9 KB
/
CMakeLists.txt
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
Project(EnergyPlus)
CMAKE_MINIMUM_REQUIRED(VERSION 2.8)
set( CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake" ${CMAKE_MODULE_PATH} )
set( CMAKE_VERSION_MAJOR 8 )
set( CMAKE_VERSION_MINOR 3 )
set( CMAKE_VERSION_PATCH 4 )
set( PREV_RELEASE_SHA "6d97d07" )
set( ENERGYPLUS_VERSION "${CMAKE_VERSION_MAJOR}.${CMAKE_VERSION_MINOR}.${CMAKE_VERSION_PATCH}" )
set( CMAKE_VERSION_BUILD "Unknown" CACHE STRING "Build number" )
find_package(Git)
if(NOT GIT_FOUND)
find_program(GIT_EXECUTABLE git HINTS "$ENV{LOCALAPPDATA}/Programs/git/bin")
if (NOT GIT_EXECUTABLE_NOTFOUND)
set(GIT_FOUND TRUE)
endif()
endif()
if(GIT_FOUND)
execute_process(COMMAND "${GIT_EXECUTABLE}" "rev-parse" "--short=10" "HEAD"
WORKING_DIRECTORY "${CMAKE_SOURCE_DIR}"
TIMEOUT 10
RESULT_VARIABLE RESULT
OUTPUT_VARIABLE GIT_VERSION
ERROR_QUIET
OUTPUT_STRIP_TRAILING_WHITESPACE)
if(${RESULT} EQUAL 0 AND NOT "${GIT_VERSION}" EQUAL "${CMAKE_VERSION_BUILD}")
set(CMAKE_VERSION_BUILD ${GIT_VERSION} CACHE STRING "Build number" FORCE) # git sha
endif()
get_filename_component(GIT_DIR "${GIT_EXECUTABLE}" PATH)
else()
set(GIT_DIR "")
endif()
set(CPACK_PACKAGE_CONTACT "Kyle Benne <Kyle.Benne@nrel.gov>")
option( BUILD_PACKAGE "Build package" OFF )
option( BUILD_TESTING "Build testing targets" OFF )
option( BUILD_FORTRAN "Build Fortran stuff" OFF )
option( BUILD_VALIDATION_REPORTS "Build validation reports" OFF )
# Turning ENABLE_GTEST_DEBUG_MODE ON will cause assertions and exceptions to halt the test case and unwind.
# Turn this option OFF for automated testing.
option( ENABLE_GTEST_DEBUG_MODE "Enable options to help debug test failures" ON )
option( ENABLE_INSTALL_REMOTE "Enable install_remote and install_remote_plist commands to install files from remote resources on the internet" ON )
mark_as_advanced( ENABLE_INSTALL_REMOTE )
# we don't need all devs to have Python installed. There are 2 cases where we do want it
# 1. Doing regression testing; which would be: BUILD_TESTING AND ENABLE_REGRESSION_TESTING
# 2. Doing package building, since Python is going to be our tool for some things; thus: BUILD_PACKAGE
if( ( BUILD_TESTING AND ENABLE_REGRESSION_TESTING ) OR ( BUILD_PACKAGE ) )
find_package(PythonInterp 2.7 REQUIRED)
endif()
if( BUILD_TESTING )
option( ENABLE_REGRESSION_TESTING "Enable Regression Tests" OFF )
if( ENABLE_REGRESSION_TESTING )
if ( CMAKE_CL_64 )
set( ARCH_FLAG "-64bit" )
else()
set( ARCH_FLAG "" )
endif()
set( REGRESSION_BASELINE_SHA "" CACHE STRING "SHA of baseline comparison" )
set( COMMIT_SHA "" CACHE STRING "Commit sha of this build" )
set( REGRESSION_SCRIPT_PATH "" CACHE PATH "Path to regression scripts" )
set( REGRESSION_BASELINE_PATH "" CACHE PATH "Path to energyplus baseline folder to compare against" )
set( DEVICE_ID "${CMAKE_SYSTEM_NAME}-${CMAKE_CXX_COMPILER_ID}${ARCH_FLAG}" CACHE STRING "Identifier for this device configuration" )
endif()
endif()
if( ENABLE_REGRESSION_TESTING )
string(STRIP "${REGRESSION_SCRIPT_PATH}" REG_PATH_STRIPPED)
string(STRIP "${REGRESSION_BASELINE_PATH}" REG_BASELINE_STRIPPED)
if (REG_PATH_STRIPPED STREQUAL "" OR REG_BASELINE_STRIPPED STREQUAL "")
message( "Regression testing is enabled, but no script or baseline has been provided" )
set( DO_REGRESSION_TESTING OFF )
else()
set( DO_REGRESSION_TESTING ON )
endif()
endif()
if( UNIX AND NOT APPLE )
set(CMAKE_INSTALL_RPATH "$ORIGIN")
endif()
if ( MSVC AND NOT ( "${CMAKE_CXX_COMPILER_ID}" STREQUAL "Intel" ) )
if (CMAKE_C_COMPILER_VERSION VERSION_LESS "18.00.30723")
message(FATAL_ERROR "Visual Studio 2013 Update 3 or Greater Required")
endif()
set(gtest_force_shared_crt ON)
endif()
if (MINGW)
set(CMAKE_SHARED_LIBRARY_PREFIX "")
endif ()
set( CMAKE_LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/Products" )
set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/Products" )
set( CMAKE_RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/Products" )
# Advanced, time consuming compiler optimization options
option(ENABLE_LTO "Enable link-time-optimization" FALSE)
option(PROFILE_GENERATE "Generate profile data" FALSE)
option(PROFILE_USE "Use profile data" FALSE)
if (PROFILE_USE AND PROFILE_GENERATE)
message(SEND_ERROR "Cannot enable PROFILE_USE and PROFILE_GENERATE simultaneously")
endif()
include(cmake/ProjectMacros.cmake)
include(cmake/CompilerFlags.cmake)
INCLUDE_DIRECTORIES( ${CMAKE_SOURCE_DIR}/third_party )
INCLUDE_DIRECTORIES( ${CMAKE_SOURCE_DIR}/third_party/zlib )
INCLUDE_DIRECTORIES( ${CMAKE_SOURCE_DIR}/third_party/gtest/include/ SYSTEM )
INCLUDE_DIRECTORIES( ${CMAKE_SOURCE_DIR}/third_party/ObjexxFCL/src/ )
INCLUDE_DIRECTORIES( ${CMAKE_SOURCE_DIR}/third_party/SQLite/ SYSTEM )
INCLUDE_DIRECTORIES( "${CMAKE_SOURCE_DIR}/third_party/Expat" "${CMAKE_SOURCE_DIR}/third_party/Expat/lib" SYSTEM)
INCLUDE_DIRECTORIES( ${CMAKE_SOURCE_DIR}/third_party/CLI/ )
INCLUDE_DIRECTORIES( ${CMAKE_SOURCE_DIR}/third_party/jsoncpp)
if( BUILD_TESTING )
option( TEST_ANNUAL_SIMULATION "Use annual simulations for tests instead of only design days" OFF )
enable_testing()
include(CTest)
endif()
# E+ required libraries
ADD_SUBDIRECTORY(third_party/SQLite)
ADD_SUBDIRECTORY(third_party/ObjexxFCL)
ADD_SUBDIRECTORY(third_party/BCVTB)
ADD_SUBDIRECTORY(third_party/Expat)
ADD_SUBDIRECTORY(third_party/FMI)
ADD_SUBDIRECTORY(third_party/zlib)
ADD_SUBDIRECTORY(third_party/DElight)
IF(NOT APPLE )
ADD_SUBDIRECTORY(third_party/FMUParser)
ENDIF()
ADD_SUBDIRECTORY(third_party/jsoncpp)
# of course E+ itself
ADD_SUBDIRECTORY(src/EnergyPlus)
if( BUILD_TESTING )
ADD_SUBDIRECTORY(third_party/gtest)
ADD_SUBDIRECTORY(testfiles)
ADD_SUBDIRECTORY(tst/EnergyPlus/unit)
ADD_SUBDIRECTORY(tst/jsoncpp/unit)
endif()
if( BUILD_FORTRAN )
include(CMakeAddFortranSubdirectory)
cmake_add_fortran_subdirectory(src/ExpandObjects PROJECT ExpandObjects NO_EXTERNAL_INSTALL )
cmake_add_fortran_subdirectory(src/ReadVars PROJECT ReadVars NO_EXTERNAL_INSTALL )
set(TRANSITION_EXTRA_FLAGS "-DCMAKE_VERSION_MAJOR:STRING=${CMAKE_VERSION_MAJOR}" "-DCMAKE_VERSION_MINOR:STRING=${CMAKE_VERSION_MINOR}" "-DCMAKE_VERSION_PATCH:STRING=${CMAKE_VERSION_PATCH}")
cmake_add_fortran_subdirectory(src/Transition PROJECT Transition CMAKE_COMMAND_LINE ${TRANSITION_EXTRA_FLAGS} NO_EXTERNAL_INSTALL )
cmake_add_fortran_subdirectory(src/Basement PROJECT Basement NO_EXTERNAL_INSTALL )
cmake_add_fortran_subdirectory(src/HVAC-Diagram PROJECT HVAC-Diagram NO_EXTERNAL_INSTALL )
cmake_add_fortran_subdirectory(src/ParametricPreprocessor PROJECT ParametricPreprocessor NO_EXTERNAL_INSTALL )
cmake_add_fortran_subdirectory(src/Slab PROJECT Slab NO_EXTERNAL_INSTALL )
cmake_add_fortran_subdirectory(src/ConvertESOMTR PROJECT ConvertESOMTR NO_EXTERNAL_INSTALL )
endif()
configure_file( idd/Energy+.idd.in "${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/Energy+.idd" )
configure_file( idd/BasementGHT.idd "${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/BasementGHT.idd" )
configure_file( idd/SlabGHT.idd "${CMAKE_RUNTIME_OUTPUT_DIRECTORY}/SlabGHT.idd" )
if( BUILD_PACKAGE )
set(CPACK_INSTALL_CMAKE_PROJECTS
"${CMAKE_BINARY_DIR};EnergyPlus;ALL;/"
)
if( BUILD_FORTRAN )
list(APPEND CPACK_INSTALL_CMAKE_PROJECTS "${CMAKE_BINARY_DIR}/src/ExpandObjects/;ExpandObjects;ALL;/")
list(APPEND CPACK_INSTALL_CMAKE_PROJECTS "${CMAKE_BINARY_DIR}/src/ReadVars/;ReadVars;ALL;/")
list(APPEND CPACK_INSTALL_CMAKE_PROJECTS "${CMAKE_BINARY_DIR}/src/Transition/;Transition;ALL;/")
list(APPEND CPACK_INSTALL_CMAKE_PROJECTS "${CMAKE_BINARY_DIR}/src/Basement/;Basement;ALL;/")
list(APPEND CPACK_INSTALL_CMAKE_PROJECTS "${CMAKE_BINARY_DIR}/src/HVAC-Diagram/;HVAC-Diagram;ALL;/")
list(APPEND CPACK_INSTALL_CMAKE_PROJECTS "${CMAKE_BINARY_DIR}/src/ParametricPreprocessor/;ParametricPreprocessor;ALL;/")
list(APPEND CPACK_INSTALL_CMAKE_PROJECTS "${CMAKE_BINARY_DIR}/src/Slab/;Slab;ALL;/")
list(APPEND CPACK_INSTALL_CMAKE_PROJECTS "${CMAKE_BINARY_DIR}/src/ConvertESOMTR/;ConvertESOMTR;ALL;/")
endif()
include(cmake/Install.cmake)
endif()
set(OPTIMIZABLE_TARGETS
sqlite objexx bcvtb epexpat epfmiimport miniziplib DElight energyplus energyplusapi energypluslib energypluslib2
)
if(NOT APPLE AND NOT MSVC)
list(APPEND OPTIMIZABLE_TARGETS parser)
endif()
if(NOT MSVC)
list(APPEND OPTIMIZABLE_TARGETS objexx_tests energyplus_tests)
endif()
if(MSVC AND (PROFILE_GENERATE OR PROFILE_USE OR ENABLE_LTO) )
get_filename_component(LINKER_DIR "${CMAKE_LINKER}" PATH)
get_filename_component(LINKER_DIR_NAME "${LINKER_DIR}" NAME)
if (MSVC12)
set(PGORTVER "120")
elseif(MSVC14)
set(PGORTVER "140")
endif()
message("Examining ${LINKER_DIR_NAME} for PGO RT DLL")
if ("${LINKER_DIR_NAME}" MATCHES ".*amd64.*")
get_filename_component(LINKER_PARENT_DIR "${LINKER_DIR}" PATH)
set(PGORTDIR "${LINKER_PARENT_DIR}/amd64")
message("Retrieving amd64 PGO dll from: ${PGORTDIR}")
else()
set(PGORTDIR "${LINKER_DIR}")
endif()
file(COPY "${PGORTDIR}/pgort${PGORTVER}.dll" DESTINATION "${CMAKE_BINARY_DIR}/Products/Release" )
foreach(target ${OPTIMIZABLE_TARGETS})
get_target_property(targ_link_flags ${target} LINK_FLAGS)
get_target_property(targ_static_link_flags ${target} STATIC_LIBRARY_FLAGS)
get_target_property(targ_compile_flags ${target} COMPILE_FLAGS)
# message("${target}: ${targ_link_flags}; ${targ_static_link_flags}; ${targ_compile_flags}")
if(targ_link_flags STREQUAL "targ_link_flags-NOTFOUND")
set(targ_link_flags "")
endif()
if(targ_static_link_flags STREQUAL "targ_static_link_flags-NOTFOUND")
set(targ_static_link_flags "")
endif()
if(targ_compile_flags STREQUAL "targ_compile_flags-NOTFOUND")
set(targ_compile_flags "")
endif()
if (ENABLE_LTO OR PROFILE_GENERATE OR PROFILE_USE)
set(targ_compile_flags "${targ_compile_flags} /GL")
endif()
if(ENABLE_LTO AND NOT PROFILE_GENERATE AND NOT PROFILE_USE)
set(targ_link_flags "${targ_link_flags} /LTCG")
set(targ_static_link_flags "${targ_static_link_flags} /LTCG")
endif()
if (PROFILE_GENERATE)
set(targ_link_flags "${targ_link_flags} /LTCG:PGI")
set(targ_static_link_flags "${targ_static_link_flags} /LTCG")
endif()
if (PROFILE_USE)
set(targ_link_flags "${targ_link_flags} /LTCG:PGO")
set(targ_static_link_flags "${targ_static_link_flags} /LTCG")
endif()
set_target_properties(${target} PROPERTIES LINK_FLAGS "${targ_link_flags}" STATIC_LIBRARY_FLAGS "${targ_static_link_flags}"
COMPILE_FLAGS "${targ_compile_flags}")
endforeach()
elseif (CMAKE_COMPILER_IS_GNUCXX)
if(ENABLE_LTO)
set_target_properties(${OPTIMIZABLE_TARGETS}
PROPERTIES LINK_FLAGS "-flto=7 -fno-use-linker-plugin" COMPILE_FLAGS "-flto=7 -fno-use-linker-plugin")
set_target_properties(energyplus
PROPERTIES LINK_FLAGS "-flto=7 -fuse-linker-plugin -fwhole-program" COMPILE_FLAGS "-flto=7 -fuse-linker-plugin -fwhole-program")
endif()
if (PROFILE_GENERATE)
set_target_properties(${OPTIMIZABLE_TARGETS} energyplus_tests TestEnergyPlusCallbacks
PROPERTIES LINK_FLAGS "-fprofile-generate" COMPILE_FLAGS "-fprofile-generate")
endif()
if (PROFILE_USE)
set_target_properties(${OPTIMIZABLE_TARGETS}
PROPERTIES LINK_FLAGS "-fprofile-use" COMPILE_FLAGS "-fprofile-use")
endif()
if (PROFILE_USE AND ENABLE_LTO)
set_target_properties(${OPTIMIZABLE_TARGETS}
PROPERTIES LINK_FLAGS "-flto=7 -fno-use-linker-plugin -fprofile-use" COMPILE_FLAGS "-flto=7 -fno-use-linker-plugin -fprofile-use")
set_target_properties(energyplus
PROPERTIES LINK_FLAGS "-flto=7 -fuse-linker-plugin -fwhole-program -fprofile-use" COMPILE_FLAGS "-flto=7 -fuse-linker-plugin -fwhole-program -fprofile-use")
endif()
elseif ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang" ) # Clang
if(ENABLE_LTO)
set_target_properties(energyplus
PROPERTIES LINK_FLAGS "-flto" COMPILE_FLAGS "-flto")
endif()
if (PROFILE_GENERATE)
set_target_properties(${OPTIMIZABLE_TARGETS}
PROPERTIES LINK_FLAGS "-fprofile-instr-generate" COMPILE_FLAGS "-fprofile-instr-generate")
endif()
if (PROFILE_USE)
set_target_properties(${OPTIMIZABLE_TARGETS}
PROPERTIES LINK_FLAGS "-fprofile-instr-use=${CMAKE_BINARY_DIR}/profdata" COMPILE_FLAGS "-fprofile-instr-use=${CMAKE_BINARY_DIR}/profdata")
endif()
if (PROFILE_USE AND ENABLE_LTO)
set_target_properties(${OPTIMIZABLE_TARGETS}
PROPERTIES LINK_FLAGS "-flto -fprofile-instr-use=${CMAKE_BINARY_DIR}/profdata" COMPILE_FLAGS "-flto -fprofile-instr-use=${CMAKE_BINARY_DIR}/profdata")
endif()
endif()
if (BUILD_VALIDATION_REPORTS)
include(ExternalProject)
ExternalProject_Add(ValidationReports
DEPENDS energyplus ReadVarsESO Basement Slab
GIT_REPOSITORY git://github.com/NREL/EnergyPlusValidationReports
GIT_TAG master
CMAKE_CACHE_ARGS
-DENERGYPLUS_PATH:PATH=${CMAKE_BINARY_DIR}
-DENERGYPLUS_VERSION:STRING=${CMAKE_VERSION_MAJOR}.${CMAKE_VERSION_MINOR}.${CMAKE_VERSION_PATCH}-${CMAKE_VERSION_BUILD}
INSTALL_COMMAND ""
)
endif()