-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathPARSER.PAS
672 lines (559 loc) · 26.4 KB
/
PARSER.PAS
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
(**************************************************************************)
(* Programmname : PARSER.PAS *)
(* Programmautor : Michael Rippl *)
(* Compiler : Turbo Pascal V5.0 *)
(* Letzte Änderung : 13-Apr-1990 *)
(* Inhalt : Syntaxüberprüfung und Codegenerierung von PASCAL.PAS *)
(* Bemerkung : Include Datei von PASCAL.PAS *)
(**************************************************************************)
(* Übersetzung eines Prozedurkörpers *)
PROCEDURE Block(Symbols : SymbolSet; Level : INTEGER; ProcElement : pNode;
IsFunction : BOOLEAN);
VAR StackCorrection, (* Stack-Korrektur *)
WithLevel, (* Level von With *)
DataOffset : INTEGER; (* Stackoffset *)
GotoRemember, (* Unvollständige Goto's *)
LabelRemember, (* Deklarierte Labels *)
PointerRemember, (* Zeiger *)
ProcedureRemember : pRing; (* Forward-Prozeduren *)
Elt : pNode;
FoundAt,
NrOfBytes : INTEGER; (* Schreiben in Datei *)
Dummy : pType; (* Dummy für Funktionen *)
(*$I TYPE.PAS*) (* Datentypen, Konstanten *)
(*$I DECLARA.PAS*) (* Deklarationen *)
(* Sprungmarken auswerten *)
PROCEDURE LabelStatement(Symbols : SymbolSet);
VAR Elt : pNode;
Found : BOOLEAN;
BEGIN
Search(Id, Level, Elt, Found);
IF NOT Found THEN Error(75) (* Label nicht deklariert *)
ELSE IF Elt^.Adr <> NilAddress THEN Error(76) (* Label zweimal definiert *)
ELSE
BEGIN
DeleteElement(LabelRemember, Elt); (* Gemerktes Label löschen *)
Elt^.Adr := ProgCount; (* Aktuelle Adresse *)
Elt^.Stack := StackCorrection; (* Stack-Korrektur *)
END;
InSymbol;
IF Sym = Colon THEN InSymbol
ELSE Error(37); (* Symbol : erwartet *)
Match(Symbols, [ ], 6);
END; (* LabelStatement *)
(* Pascal-Anweisungen auswerten *)
PROCEDURE Statement(Symbols : SymbolSet);
VAR Elt : pNode;
FoundAt : INTEGER;
(* Vorwärtsdeklariert *)
(* Einfache Ausdrücke (getrennt durch <, <=, <>, >, >=, =, in) auswerten *)
PROCEDURE Expression(Symbols : SymbolSet; VAR Item : Node); FORWARD;
(* Selektoren von Arrays, Records und Pointern auswerten *)
PROCEDURE Selector(Symbols : SymbolSet; VAR Item : Node);
VAR Elt : pNode;
Found : BOOLEAN;
Index : Node;
BEGIN
REPEAT
IF Sym = Period THEN (* Verbundvariable *)
BEGIN
InSymbol;
IF Sym <> Identifier THEN Error(20) (* Bezeichner erwartet *)
ELSE
BEGIN
IF Item.Typ <> Records THEN Error(142) (* Record erwartet *)
ELSE
BEGIN
IF Level = LevelMax THEN Fatal(3); (* Leveltabelle voll *)
Level := Level + 1;
Display[Level] :=
Item.Ref^.RecordTree; (* Teilbaum des Records *)
Search(Id, Level, Elt, Found); (* Verbundvariable suchen *)
IF Found THEN
BEGIN
Item := Elt^;
IF Item.Adr <> 0 THEN Emit1(AddOffset, Item.Adr);
END
ELSE Error(73); (* Bezeichner unbekannt *)
Display[Level] := NIL; (* Teilbaum wieder löschen *)
Level := Level - 1;
END;
InSymbol;
END;
END
ELSE IF Sym = PointerTo THEN (* Zeigervariable *)
BEGIN
InSymbol;
WITH Item DO
BEGIN
IF (Typ <> Pointers) OR (Obj <> Variables) THEN
Error(146) (* Keine Zeigervariable *)
ELSE
BEGIN
Emit(LoadIndirectToTop); (* Inhalt ist Adresse *)
Emit(CheckPointerAddress); (* Nil-Zugriff prüfen *)
Ref := Ref^.PointerType; (* Typ-Referenz vom Zeiger *)
Typ := Ref^.Typ;
Size := Ref^.Size;
END;
END;
END
ELSE (* Feldvariable *)
BEGIN
IF Sym <> LeftBrack THEN Error(21); (* Symbol [ erwartet *)
REPEAT (* Index auswerten *)
InSymbol;
Expression([Comma, RightBrack] + Symbols, Index);
IF Item.Typ = Arrays THEN
BEGIN
WITH Item DO
BEGIN
IF Ref^.IndexType^.RangeType <> Index.Ref THEN
Error(120) (* Inkompatibler Indextyp *)
ELSE
BEGIN
IF Index.Obj = Constants THEN (* Konstanter Index *)
BEGIN
IF (Index.Value < Ref^.IndexType^.RangeLow) OR
(Index.Value > Ref^.IndexType^.RangeHigh) THEN
Error(200) (* Unzulässiger Index *)
ELSE IF Ref^.ElementType^.Size = 1 THEN
Emit1(SimpleArrayIndex, Ref^.IndexType^.RangeLow)
ELSE
BEGIN
Emit1(LoadInteger, Ref^.ElementType^.Size);
Emit1(ArrayIndex, Ref^.IndexType^.RangeLow);
END;
END
ELSE (* Variabler Index *)
BEGIN
Emit1(LoadInteger, Ref^.IndexType^.RangeHigh);
Emit1(CheckArrayIndex, Ref^.IndexType^.RangeLow);
IF Ref^.ElementType^.Size = 1 THEN
Emit1(SimpleArrayIndex, Ref^.IndexType^.RangeLow)
ELSE
BEGIN
Emit1(LoadInteger, Ref^.ElementType^.Size);
Emit1(ArrayIndex, Ref^.IndexType^.RangeLow);
END;
END;
END;
WITH Item DO
BEGIN
Ref := Ref^.ElementType; (* Nächste Dimension *)
Typ := Ref^.Typ;
Size := Ref^.Size;
END;
END;
END
ELSE Error(147); (* Array erwartet *)
UNTIL Sym <> Comma;
IF Sym = RightBrack THEN InSymbol
ELSE
BEGIN
Error(22); (* Symbol ] erwartet *)
IF Sym = RightParent THEN InSymbol;
END;
END;
UNTIL NOT (Sym IN [LeftBrack, LeftParent, Period, PointerTo]);
Match(Symbols, [ ], 6);
END; (* Selector *)
(* Lädt die Adresse einer Variablen auf den Stack *)
PROCEDURE LoadVarAddress(Symbols : SymbolSet; FoundAt : INTEGER;
VAR Item : Node);
VAR OutputCode : Orders;
BEGIN
IF (WithLevel > 0) AND (FoundAt > Level - WithLevel) THEN
BEGIN
Emit1(LoadWithAddress, (WithLevel - (Level - FoundAt)) - 1);
IF Item.Adr <> 0 THEN Emit1(AddOffset, Item.Adr);
END
ELSE
BEGIN
IF Item.Nrm THEN
OutputCode := LoadAddress (* Normale Variable *)
ELSE OutputCode := LoadValue; (* Parameter *)
Emit2(OutputCode, Item.Lev, Item.Adr);
END;
IF Sym IN [LeftBrack, LeftParent, Period, PointerTo] THEN
Selector(Symbols, Item);
END; (* LoadVarAddress *)
(* Prozeduraufruf auswerten *)
PROCEDURE Call(Symbols : SymbolSet; CalledProcedure : pNode);
VAR Parameter : pNode; (* Aktueller Parameter *)
RingElt : pRing; (* Aktuelles Ringelement *)
Item : Node; (* Arithmetischer Ausdruck *)
CallRem, (* Call merken *)
Elt : pNode;
FoundAt : INTEGER;
BEGIN
WITH CalledProcedure^ DO
BEGIN
IF (Adr = IsForward) OR (Adr = NilAddress) THEN
BEGIN (* Call ohne Zieladresse *)
new(CallRem);
CallRem^ := CalledProcedure^; (* Inhalt merken *)
CallRem^.CallCount := ProgCount; (* Programmzähler merken *)
CallRem^.ProcAdr := CalledProcedure; (* Daten später bearbeiten *)
IF Adr = IsForward THEN Push(ForwardCall[Lev], CallRem, NIL)
ELSE Push(ForwardCall[Lev + 1], CallRem, NIL);
END;
Emit1(MarkStack, VarSize); (* Aufruf vorbereiten *)
RingElt := Par; (* Zeigt auf Listenkopf *)
END;
IF Sym = LeftParent THEN
BEGIN
REPEAT
InSymbol;
IF RingElt^.Next = CalledProcedure^.Par THEN
BEGIN
Error(132); (* Zu viele Parameter *)
IF Sym IN FactBegSym THEN
Expression([Comma, RightParent] + Symbols, Item);
END
ELSE
BEGIN
RingElt := RingElt^.Next;
Parameter := RingElt^.ObjectContent; (* Aktueller Parameter *)
IF Parameter^.Nrm THEN (* Call By Value *)
BEGIN
Expression([Comma, RightParent] + Symbols, Item);
IF (Parameter^.Typ = Subranges) AND (* Unterbereiche *)
(Item.Typ IN [Ints, Bools, Chars, Enumerations]) THEN
BEGIN
IF Parameter^.Ref^.RangeType = Item.Ref THEN
BEGIN
IF Item.Obj = Constants THEN (* Konstanter Ausdruck *)
BEGIN
IF (Item.Value < Parameter^.Ref^.RangeLow) OR
(Item.Value > Parameter^.Ref^.RangeHigh) THEN
Error(203); (* Unzulässige Konstante *)
END
ELSE
BEGIN
Emit1(LoadInteger, Item.Ref^.RangeHigh);
Emit1(CheckConstantRange, Item.Ref^.RangeLow);
END;
END
ELSE Error(134); (* Unzulässiger Parameter *)
END
ELSE IF (Parameter^.Typ = Arrays) AND (* Ganze Felder, Strings *)
(Item.Typ IN [Strings, Arrays]) THEN
BEGIN
IF Item.Typ = Arrays THEN (* Ganze Felder *)
BEGIN
IF Parameter^.Ref <> Item.Ref THEN Error(134);
IF Item.Ref^.ElementType^.Typ <> Chars THEN
Emit1(LoadBlock, Item.Size);
END
ELSE (* Strings *)
BEGIN
IF (Parameter^.Ref^.ElementType^.Typ <> Chars) OR
(Parameter^.Size <> Item.Size) THEN
Error(134);
END;
END
ELSE IF Parameter^.Typ = Item.Typ THEN (* Typengleichheit *)
BEGIN
IF Item.Typ IN ScalarTypes THEN
BEGIN
IF Item.Typ = Pointers THEN
BEGIN
IF Item.Obj <> Constants THEN (* Keine Nil Konstante *)
IF Parameter^.Ref <> Item.Ref THEN
Error(134);
END
ELSE IF Parameter^.Ref <> Item.Ref THEN Error(134);
END
ELSE IF Item.Typ = Sets THEN (* Mengen *)
BEGIN
; (* Nicht implmentiert *)
END
ELSE IF Item.Typ = Records THEN (* Records *)
BEGIN
IF Parameter^.Ref <> Item.Ref THEN Error(134);
Emit1(LoadBlock, Item.Size);
END;
END
ELSE IF (Parameter^.Typ = Reals) AND (Item.Typ = Ints) THEN
Emit1(IntegerToReal, 0)
ELSE IF (Parameter^.Typ <> NoType) AND (Item.Typ <> NoType) THEN
Error(134); (* Unzulässiger Parameter *)
END
ELSE (* Call By Reference *)
BEGIN
IF Sym <> Identifier THEN
BEGIN
Error(20); (* Bezeichner erwartet *)
IF Sym IN FactBegSym THEN
Expression([Comma, RightParent] + Symbols, Item);
END
ELSE
BEGIN
Locate(Id, Level, Elt, FoundAt);
InSymbol;
IF FoundAt >= 0 THEN
BEGIN
Item := Elt^;
LoadVarAddress([Comma, RightParent] + Symbols, FoundAt,
Item); (* Adresse auf Stack *)
IF (Item.Obj <> Variables) THEN
Error(66) (* Variable erwartet *)
ELSE IF Parameter^.Ref <> Item.Ref THEN Error(134);
END;
END;
END;
END;
Match([Comma, RightParent], Symbols, 6);
UNTIL Sym <> Comma;
IF Sym = RightParent THEN InSymbol
ELSE Error(41); (* Symbol ) erwartet *)
END;
WITH CalledProcedure^ DO
BEGIN
IF RingElt^.Next <> Par THEN Error(131); (* Zu wenig Parameter *)
Emit2(CallProcedure, Lev, ParSize - 1);
IF (Adr = IsForward) OR (Adr = NilAddress) THEN
BEGIN (* Call ohne Zieladresse *)
new(CallRem);
CallRem^ := CalledProcedure^; (* Inhalt merken *)
CallRem^.CallCount := ProgCount; (* Programmzähler merken *)
CallRem^.ProcAdr := CalledProcedure; (* Daten später bearbeiten *)
IF Adr = IsForward THEN Push(ForwardCall[Lev], CallRem, NIL)
ELSE Push(ForwardCall[Lev + 1], CallRem, NIL);
END;
Emit1(Jump, Adr);
IF Lev < Level THEN Emit2(UpdateDisplay, Lev, Level);
END;
END; (* Call *)
(*$I EXPRESS.PAS*) (* Arithmetische Ausdrücke *)
(*$I STATEMEN.PAS*) (* Pascal-Anweisungen *)
BEGIN (* Statement *)
IF Sym IN [Identifier] + StateBegSym THEN
BEGIN
CASE Sym OF
Identifier :
BEGIN
Locate(Id, Level, Elt, FoundAt);
InSymbol;
IF FoundAt >= 0 THEN
BEGIN
CASE Elt^.Obj OF
Nothing :
;
Constants, Datatypes :
Error(52); (* Fehler in Anweisung *)
Variables :
Assignment(Elt^, FoundAt); (* Variablenzuweisung *)
Procedures :
IF FoundAt > 0 THEN Call(Symbols, Elt)
ELSE StandardProcedure(Elt^.Adr);
Functions :
BEGIN
IF ProcElement <> Elt THEN
Error(160); (* Unzulässige Zuweisung *)
Assignment(Elt^, FoundAt);
END;
END;
END;
END;
GotoSy : GotoStatement;
WithSy : WithStatement;
BeginSy : CompoundStatement;
IfSy : IfStatement;
CaseSy : CaseStatement;
WhileSy : WhileStatement;
RepeatSy : RepeatStatement;
ForSy : ForStatement;
END;
END;
Match(Symbols, [ ], 23); (* Symbol ; erwartet *)
END; (* Statement *)
BEGIN (* Block *)
DataOffset := ProcOffset; (* Ab hier Variablen *)
IF ProcElement^.Adr <> IsMainProg THEN
Match([LeftParent, Colon, Semicolon], [ForwardSy] + Symbols, 133);
IF ProcElement^.Adr <> IsForward THEN (* Keine Forward-Prozedur *)
BEGIN
IF Sym = LeftParent THEN ParameterList; (* Parameter eintragen *)
ProcElement^.ParSize := DataOffset;
IF IsFunction THEN (* Funktionsdeklaration *)
BEGIN
IF Sym = Colon THEN InSymbol
ELSE Error(37); (* Symbol : erwartet *)
IF Sym = Identifier THEN
BEGIN
Locate(Id, Level, Elt, FoundAt); (* Bezeichner suchen *)
IF FoundAt >= 0 THEN
BEGIN
IF Elt^.Obj <> Datatypes THEN
Error(141) (* Datentyp erwartet *)
ELSE IF Elt^.Typ IN ScalarTypes THEN
BEGIN
WITH ProcElement^ DO
BEGIN
Ref := Elt^.Ref; (* Typ-Referenz *)
Typ := Ref^.Typ;
Size := Ref^.Size;
END;
END
ELSE Error(88); (* Nur skalar oder einfach *)
END;
InSymbol;
END
ELSE
BEGIN
Error(129); (* Typbezeichner erwartet *)
IF Sym IN TypeBegSym THEN Typ([Semicolon] + Symbols, Dummy);
END;
END;
END
ELSE DataOffset := ProcElement^.ParSize; (* Parameter beachten *)
IF Sym = Semicolon THEN InSymbol
ELSE Skip([ForwardSy] + Symbols, 23); (* Symbol ; erwartet *)
IF Sym = ForwardSy THEN (* Forward Deklaration *)
BEGIN
InSymbol;
IF ProcElement^.Adr = IsMainProg THEN
Fatal(6); (* Programm nicht Forward *)
IF ProcElement^.Adr = IsForward THEN
Error(62) (* Prozedurkörper erwartet *)
ELSE
BEGIN
ProcElement^.Rem := Display[Level]; (* Parameter merken *)
ProcElement^.Adr := IsForward; (* Vorwärtsdeklaration *)
Display[Level] := NIL; (* Parameter entfernen *)
END;
END
ELSE (* Prozedurdeklaration *)
BEGIN
CreateRing(PointerRemember); (* Zeiger merken *)
CreateRing(ProcedureRemember); (* Prozeduren merken *)
CreateRing(LabelRemember); (* Labels merken *)
WHILE Sym IN [LabelSy, ConstSy, TypeSy, VarSy, ProcedureSy, FunctionSy] DO
BEGIN
CASE Sym OF
LabelSy : LabelDeclaration;
ConstSy : ConstantDeclaration;
TypeSy : TypeDeclaration;
VarSy : VariableDeclaration;
ProcedureSy, FunctionSy :
BEGIN
IF NOT RingIsEmpty(PointerRemember) THEN
CompletePointer; (* Zeiger vervollständigen *)
ProcedureDeclaration;
END;
END;
END;
IF DataOffset > StackMax THEN Fatal(7) (* Nicht genug Speicher *)
ELSE ProcElement^.VarSize := DataOffset; (* Variablengröße merken *)
ProcElement^.Adr := ProgCount; (* Adresse der Prozedur *)
StackCorrection := 0; (* Korrekturwert für Goto *)
WithLevel := 0; (* Leveltiefe von With *)
Match([BeginSy], Symbols, 38); (* Symbol begin erwartet *)
IF NOT RingIsEmpty(ProcedureRemember) THEN
Error(84); (* Undefinierte Prozeduren *)
IF NOT RingIsEmpty(PointerRemember) THEN
CompletePointer; (* Zeiger vervollständigen *)
WHILE NOT RingIsEmpty(ForwardCall[Level]) DO (* Call's ohne Zieladresse *)
BEGIN
Pop(ForwardCall[Level], Elt, Dummy);
CreateRing(Elt^.Par); (* Für Löschen wichtig *)
Push(Remember[Level], Elt, NIL); (* Zum Löschen merken *)
WITH Elt^ DO (* Variablengröße *)
Code^[CallCount].y := ProcAdr^.VarSize;
Pop(ForwardCall[Level], Elt, Dummy);
CreateRing(Elt^.Par); (* Für Löschen wichtig *)
Push(Remember[Level], Elt, NIL); (* Zum Löschen merken *)
WITH Elt^ DO (* Zieladresse *)
Code^[CallCount].y := ProcAdr^.Adr;
END;
DeleteRing(PointerRemember); (* Liste komplett löschen *)
DeleteRing(ProcedureRemember); (* Liste komplett löschen *)
CreateRing(GotoRemember); (* Goto's merken *)
IF Sym = BeginSy THEN InSymbol; (* Kein Compound-Statement *)
(* Ab hier Anweisungsteil *)
WHILE Sym = IntConst DO (* Labels auswerten *)
LabelStatement([Semicolon, EndSy, IntConst, Identifier] + Symbols);
Statement([Semicolon, EndSy] + Symbols); (* Anweisungen auswerten *)
WHILE Sym IN [Semicolon] + StateBegSym DO
BEGIN
IF Sym = Semicolon THEN InSymbol
ELSE Error(23); (* Symbol ; erwartet *)
WHILE Sym = IntConst DO (* Labels auswerten *)
LabelStatement([Semicolon, EndSy, IntConst, Identifier] + Symbols);
Statement([Semicolon, EndSy] + Symbols); (* Anweisungen auswerten *)
END;
IF Sym = EndSy THEN InSymbol
ELSE Error(40); (* Symbol end erwartet *)
IF NOT RingIsEmpty(LabelRemember) THEN
Error(83); (* Undefinierte Labels *)
WHILE NOT RingIsEmpty(GotoRemember) DO (* Goto ohne Zieladresse *)
BEGIN
Pop(GotoRemember, Elt, Dummy);
WITH Elt^ DO
BEGIN
Code^[Count].y := LabelAdr^.Stack - Correct;
Code^[Count + 1].y := LabelAdr^.Adr; (* Zieladresse eintragen *)
END;
END;
DeleteLevel(Level); (* Binärbaum löschen *)
DeleteRing(GotoRemember); (* Liste komplett löschen *)
DeleteRing(LabelRemember); (* Liste komplett löschen *)
END;
Match([Period, Semicolon] + Symbols, [ ], 6);
END; (* Block *)
(* Überprüfung und Übersetzung starten *)
PROCEDURE Parser;
VAR Elt : pNode;
Found : BOOLEAN;
NrOfBytes : INTEGER;
BEGIN
InSymbol;
IF Sym <> ProgramSy THEN Fatal(5); (* Symbol program erwartet *)
InSymbol;
IF Sym = Identifier THEN
BEGIN
ProgramName := Id; (* Programmname merken *)
InSymbol;
END
ELSE Error(105); (* Programmname erwartet *)
IF Sym = LeftParent THEN
BEGIN
InSymbol;
Match([Identifier], [RightParent, Comma, Semicolon] + StateBegSym +
BlockBegSym, 20);
IF Sym = Identifier THEN InSymbol;
WHILE Sym = Comma DO
BEGIN
InSymbol;
IF Sym = Identifier THEN InSymbol
ELSE Error(20); (* Bezeichner erwartet *)
END;
IF Sym = RightParent THEN InSymbol
ELSE Error(41); (* Symbol ) erwartet *)
END;
Search('main program ', 0, Elt, Found);
Block(BlockBegSym + StateBegSym, 1, Elt, FALSE);
IF Sym <> Period THEN Error(53); (* Symbol . erwartet *)
Emit(StopProgram); (* Letzter Befehl *)
(*$I-*) (* I/O Überprüfung aus *)
blockwrite(target, Code^, sizeof(Order) * ProgCount, NrOfBytes);
IF ioresult <> 0 THEN Fatal(8); (* Fehler beim Schreiben *)
(* Anzahl der Realzahlen *)
blockwrite(target, RealIndex, sizeof(INTEGER), NrOfBytes);
(* RealTable schreiben *)
blockwrite(target, RealTable, sizeof(REAL) * RealIndex, NrOfBytes);
StringIndex := StringIndex - 1; (* Länge aller Strings *)
blockwrite(target, StringIndex, sizeof(INTEGER), NrOfBytes);
(* StringTable schreiben *)
blockwrite(target, StringTable, sizeof(CHAR) * StringIndex, NrOfBytes);
(* Adresse des Hauptprg's *)
blockwrite(target, Elt^.Adr, sizeof(INTEGER), NrOfBytes);
(* Variablengröße vom Prg. *)
blockwrite(target, Elt^.VarSize, sizeof(INTEGER), NrOfBytes);
IF ioresult <> 0 THEN Fatal(8); (* Fehler beim Schreiben *)
(*$I+*) (* I/O Überprüfung an *)
END; (* Parser *)
(* END PARSER.PAS *)