build.gradle

import java.util.concurrent.TimeUnit

// Top-level build file where you can add configuration options common to all sub-projects/modules.
buildscript {
    ext {
        useBytex = USE_BYTEX == "true"
    }

    repositories {
        google()
        mavenLocal()
        mavenCentral()
        maven { url "https://artifact.bytedance.com/repository/byteX/" }
    }
    dependencies {
        classpath "com.android.tools.build:gradle:$AGP_VERSION"
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$KOTLIN_VERSION"

        if (useBytex) {
            classpath "com.bytedance.android.byteX:base-plugin:$BYTEX_VERSION"
            classpath "io.github.porum:muddy-gradle-plugin-bytex:$VERSION"
        } else {
            classpath "io.github.porum:muddy-gradle-plugin:$VERSION"
        }
    }
}

allprojects {
    group = GROUP
    version = VERSION

    repositories {
        google()
        mavenLocal()
        mavenCentral()
        maven { url "https://artifact.bytedance.com/repository/byteX/" }
    }

    tasks.withType(Javadoc) {
        options.encoding = "UTF-8"
    }

    tasks.withType(JavaCompile) {
        options.encoding = "UTF-8"
    }
}

Properties props = new Properties()
props.load(new FileInputStream(rootProject.file("local.properties")))
project.ext {
    setProperty("sonatypeUserName", props["sonatypeUserName"])
    setProperty("sonatypePassword", props["sonatypePassword"])
    setProperty("signing.keyId", props["signing.keyId"])
    setProperty("signing.password", props["signing.password"])
    setProperty("signing.secretKeyRingFile", props["signing.secretKeyRingFile"])
}

File publishScript = project.file("publish.gradle")

subprojects {
    if (name.startsWith("muddy")) {
        apply from: publishScript
    }

    configurations.configureEach {
        resolutionStrategy.cacheChangingModulesFor(0, TimeUnit.SECONDS)
    }
}

configurations.configureEach {
    resolutionStrategy.cacheChangingModulesFor(0, TimeUnit.SECONDS)
}


task clean(type: Delete) {
    delete rootProject.buildDir
}