build.gradle

buildscript {
    repositories {
        mavenCentral()
        gradlePluginPortal()
        gradlePluginPortal()
        maven { url "https://oss.sonatype.org/content/repositories/snapshots/" }
        google()
    }
    dependencies {
        

    }
}

plugins {
    id "org.sonarqube" version "2.5"
    id 'distribution'
    id 'java'
}


def getGitCommit() {
    def cmd = 'git rev-parse --short HEAD'
    return cmd.execute().text.trim()
}

project.ext.versionName = "v0.1.0-${getGitCommit()}"


java {
    sourceCompatibility = JavaVersion.VERSION_21
    targetCompatibility = JavaVersion.VERSION_21
}

allprojects {
    apply plugin: "eclipse"
    apply plugin: "idea"
    
    version = '1.0'
    ext {
        appName = "spacefly"
        gdxVersion = '1.12.1'
        roboVMVersion = '2.3.20'
        box2DLightsVersion = '1.5'
        ashleyVersion = '1.7.4'
        aiVersion = '1.8.2'
        gdxControllersVersion = '2.2.1'
    }

    repositories {
        mavenLocal()
        mavenCentral()
        google()
        gradlePluginPortal()
        maven { url "https://oss.sonatype.org/content/repositories/snapshots/" }
        maven { url "https://oss.sonatype.org/content/repositories/releases/" }
        maven { url "https://jitpack.io" }
    }
}

project(":desktop") {
    apply plugin: "java-library"

    dependencies {
        implementation project(":core")
        api "com.badlogicgames.gdx:gdx-backend-lwjgl3:$gdxVersion"
        api "com.badlogicgames.gdx:gdx-platform:$gdxVersion:natives-desktop"
        api "com.badlogicgames.gdx:gdx-box2d-platform:$gdxVersion:natives-desktop"
        
    }
}

project(":graphics") {
    apply plugin: "base"

}

project(":core") {
    apply plugin: "java-library"

    task generateBuildConfig {
        outputs.dir file("$buildDir/generated/source/buildConfig/main")
        
        doLast {
            def outputDir = file("$buildDir/generated/source/buildConfig/main/com/vesas/spacefly")
            outputDir.mkdirs()
            new File(outputDir, "BuildConfig.java").text = """
                package com.vesas.spacefly;
                
                public final class BuildConfig {
                    public static final String VERSION_NAME = "${project.versionName}";
                    private BuildConfig() {}
                }
            """
        }
    }

    tasks.compileJava.dependsOn(generateBuildConfig)
    
    sourceSets {
        main {
            java {
                srcDir "$buildDir/generated/source/buildConfig/main"
            }
        }
    }

    dependencies {
        
        implementation project(":graphics")

        api "com.badlogicgames.gdx:gdx:$gdxVersion"
        api "com.badlogicgames.gdx:gdx-box2d:$gdxVersion"
        api "com.badlogicgames.box2dlights:box2dlights:$box2DLightsVersion"
        api "com.badlogicgames.ashley:ashley:$ashleyVersion"
        api "com.badlogicgames.gdx:gdx-ai:$aiVersion"
        
    }

}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(21)
    }
}