-
Notifications
You must be signed in to change notification settings - Fork 6
/
Copy pathbuild.gradle
219 lines (194 loc) · 9.02 KB
/
build.gradle
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
apply plugin: 'com.android.library'
project.group = 'com.wonderpush'
project.archivesBaseName = 'wonderpush-android-sdk'
project.version = "4.4.2-SNAPSHOT"
android {
compileOptions {
sourceCompatibility JavaVersion.VERSION_1_8
targetCompatibility JavaVersion.VERSION_1_8
}
defaultConfig {
compileSdk 33
minSdkVersion 21
consumerProguardFiles 'proguard-exported.pro'
testInstrumentationRunner 'androidx.test.runner.AndroidJUnitRunner'
buildConfigField 'String', 'WONDERPUSH_SDK_VERSION', '"' + project.version + '"'
}
buildTypes {
release {
minifyEnabled false
proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
}
}
useLibrary 'android.test.runner'
useLibrary 'android.test.base'
useLibrary 'android.test.mock'
resourcePrefix 'wonderpush_android_sdk_'
namespace 'com.wonderpush.sdk'
lint {
abortOnError false
}
}
dependencies {
// This is how we can declare incompatibility with previous modules.
// This way a newer SDK version can say it is not compatible with
// previous module versions, whereas the module version can only
// declare a minimal SDK version.
// Failing to publish these constraints would allow an older version
// of the module to accept the newer although incompatible SDK version.
//constraints {
// implementation('com.wonderpush:wonderpush-android-sdk-fcm:[2.0,3.0)') {
// because 'ABI changes'
// }
//}
implementation 'androidx.core:core:1.0.0' // Note: this dependency is already depended on by at least com.google.firebase:firebase-messaging:20.1.2 and com.squareup.picasso3:picasso:3.0.0-alpha05
implementation 'androidx.localbroadcastmanager:localbroadcastmanager:1.0.0' // Note: this dependency is already depended on by at least com.google.firebase:firebase-messaging:20.1.2
implementation 'androidx.constraintlayout:constraintlayout:1.1.3'
implementation 'androidx.cardview:cardview:1.0.0'
implementation 'com.google.dagger:dagger:2.24'
annotationProcessor 'com.google.dagger:dagger-compiler:2.24'
compileOnly 'com.google.code.findbugs:jsr305:3.0.2'
implementation 'javax.inject:javax.inject:1'
implementation 'io.reactivex.rxjava2:rxjava:2.1.14'
implementation 'io.reactivex.rxjava2:rxandroid:2.0.2'
implementation "com.squareup.picasso3:picasso:3.0.0-alpha05"
implementation "com.squareup.okhttp3:okhttp:4.11.0" // necessary to bump dependency from picasso 3.0.0-alpha05
implementation "com.squareup.okio:okio:3.6.0" // necessary to bump dependency from okhttp 4.11.0
//needed for webview message
implementation 'androidx.webkit:webkit:1.4.0'
// needed by openAppRating
implementation 'com.google.android.play:review:2.0.0'
testImplementation 'junit:junit:4.12'
testImplementation 'org.hamcrest:hamcrest:2.2'
testImplementation 'org.json:json:20160810'
testImplementation group: 'com.google.code.findbugs', name: 'jsr305', version: '3.0.2'
androidTestImplementation 'androidx.test.ext:junit:1.1.1'
androidTestImplementation 'androidx.test.espresso:espresso-core:3.1.0'
}
if (file('local.gradle').exists()) {
apply from: 'local.gradle'
}
tasks.withType(JavaCompile) {
options.compilerArgs << "-Xlint:unchecked" << "-Xlint:deprecation" << "-Xdiags:verbose"
}
apply plugin: 'maven-publish'
apply plugin: 'signing'
publishing {
publications {
release(MavenPublication) {
afterEvaluate {
from components.release // identical to artifact bundleReleaseAar
artifact androidSourcesJar
artifact androidJavadocsJar
}
groupId = project.group
artifactId = project.archivesBaseName
version = project.version
pom {
packaging = 'aar'
groupId = project.group
artifactId = 'wonderpush-android-sdk'
name = 'WonderPush Android SDK'
description = 'WonderPush Android SDK'
url = 'https://github.com/wonderpush/wonderpush-android-sdk'
scm {
connection = 'scm:git@github.com:wonderpush/wonderpush-android-sdk.git'
developerConnection = 'scm:git@github.com:wonderpush/wonderpush-android-sdk.git'
url = 'https://github.com/wonderpush/wonderpush-android-sdk'
}
licenses {
license {
name = 'Apache 2.0'
url = 'https://github.com/wonderpush/wonderpush-android-sdk/blob/master/LICENSE.txt'
distribution = 'repo'
}
}
developers {
developer {
id = 'wonderpush'
name = 'WonderPush'
}
}
}
}
}
repositories {
maven {
name = 'wonderpush-android-sdk-repository'
url = 'https://oss.sonatype.org/service/local/staging/deploy/maven2/'
credentials {
if (project.hasProperty('wonderpush_publishing_repositories_maven_credentials_username')) {
username = wonderpush_publishing_repositories_maven_credentials_username
}
if (project.hasProperty('wonderpush_publishing_repositories_maven_credentials_password')) {
password = wonderpush_publishing_repositories_maven_credentials_password
}
}
}
}
}
afterEvaluate {
signing {
useGpgCmd()
sign publishing.publications
sign configurations.archives
}
}
task androidJavadocs(type: Javadoc) {
title = 'WonderPush Android SDK Reference'
source = [
'src/main/java/com/wonderpush/sdk/DeepLinkEvent.java',
'src/main/java/com/wonderpush/sdk/WonderPush.java',
'src/main/java/com/wonderpush/sdk/WonderPushAbstractDelegate.java',
'src/main/java/com/wonderpush/sdk/WonderPushChannel.java',
'src/main/java/com/wonderpush/sdk/WonderPushChannelGroup.java',
'src/main/java/com/wonderpush/sdk/WonderPushDelegate.java',
'src/main/java/com/wonderpush/sdk/WonderPushFirebaseMessagingService.java',
'src/main/java/com/wonderpush/sdk/WonderPushUserPreferences.java',
'src/main/java/com/wonderpush/sdk/WonderPushInitializer.java',
'src/main/java/com/wonderpush/sdk/inappmessaging/InAppMessagingImpressionListener.java',
'src/main/java/com/wonderpush/sdk/inappmessaging/InAppMessagingClickListener.java',
'src/main/java/com/wonderpush/sdk/inappmessaging/model/Text.java',
'src/main/java/com/wonderpush/sdk/inappmessaging/model/ModalMessage.java',
'src/main/java/com/wonderpush/sdk/inappmessaging/model/Button.java',
'src/main/java/com/wonderpush/sdk/inappmessaging/model/BannerMessage.java',
'src/main/java/com/wonderpush/sdk/inappmessaging/model/CardMessage.java',
'src/main/java/com/wonderpush/sdk/inappmessaging/model/InAppMessage.java',
'src/main/java/com/wonderpush/sdk/inappmessaging/model/ImageOnlyMessage.java',
'src/main/java/com/wonderpush/sdk/inappmessaging/model/MessageType.java',
'src/main/java/com/wonderpush/sdk/inappmessaging/InAppMessagingDisplayErrorListener.java',
'src/main/java/com/wonderpush/sdk/inappmessaging/InAppMessaging.java',
'src/main/java/com/wonderpush/sdk/inappmessaging/InAppMessagingDisplayCallbacks.java',
'src/main/java/com/wonderpush/sdk/inappmessaging/InAppMessagingDisplay.java'
] //android.sourceSets.main.java.srcDirs
doFirst {
classpath = project.files(
project.android.libraryVariants.toList().first().javaCompileProvider.get().classpath.files,
project.android.getBootClasspath(),
"$projectDir/build/generated/ap_generated_sources/release/out",
"$projectDir/build/generated/ap_generated_sources/debug/out",
"$projectDir/build/intermediates/javac/release/compileReleaseJavaWithJavac/classes",
"$projectDir/build/intermediates/javac/debug/compileDebugJavaWithJavac/classes",
android.sourceSets.main.java.srcDirs
)
}
options.overview = project.rootDir.path + '/overview.html'
options.showFromPublic()
// JDK 1.8 is more strict then 1.7. Have JDK 1.8 behave like 1.7 for javadoc generation
options.addStringOption('Xdoclint:none', '-quiet')
}
project.afterEvaluate {
androidJavadocs.dependsOn(assembleDebug)
}
task androidJavadocsJar(type: Jar, dependsOn: androidJavadocs) {
archiveClassifier.set('javadoc')
from androidJavadocs.destinationDir
}
task androidSourcesJar(type: Jar) {
archiveClassifier.set('sources')
from android.sourceSets.main.java.sourceFiles
}
artifacts {
archives androidSourcesJar
archives androidJavadocsJar
}