FxaaFragment.glsl

#version 300 es
precision highp float;

out vec4 FragColor;
in vec2 texCoord;

uniform sampler2D scene;
uniform vec2 resolution;

// Settings for FXAA.
const float FXAA_SPAN_MAX = 8.0;
const float FXAA_REDUCE_MUL = 1.0 / 8.0;
const float FXAA_REDUCE_MIN = 1.0 / 128.0;

void main() {
    vec2 texOffset = 1.0 / resolution;

    vec3 rgbNW = texture(scene, texCoord + vec2(-1.0, -1.0) * texOffset).xyz;
    vec3 rgbNE = texture(scene, texCoord + vec2(1.0, -1.0) * texOffset).xyz;
    vec3 rgbSW = texture(scene, texCoord + vec2(-1.0, 1.0) * texOffset).xyz;
    vec3 rgbSE = texture(scene, texCoord + vec2(1.0, 1.0) * texOffset).xyz;
    vec3 rgbM = texture(scene, texCoord).xyz;

    vec3 luma = vec3(0.299, 0.587, 0.114);
    float lumaNW = dot(rgbNW, luma);
    float lumaNE = dot(rgbNE, luma);
    float lumaSW = dot(rgbSW, luma);
    float lumaSE = dot(rgbSE, luma);
    float lumaM = dot(rgbM, luma);
    float lumaMin = min(lumaM, min(min(lumaNW, lumaNE), min(lumaSW, lumaSE)));
    float lumaMax = max(lumaM, max(max(lumaNW, lumaNE), max(lumaSW, lumaSE)));

    vec2 dir;
    dir.x = -((lumaNW + lumaNE) - (lumaSW + lumaSE));
    dir.y = ((lumaNW + lumaSW) - (lumaNE + lumaSE));

    float dirReduce = max((lumaNW + lumaNE + lumaSW + lumaSE) * (0.25 * FXAA_REDUCE_MUL), FXAA_REDUCE_MIN);
    float rcpDirMin = 1.0 / (min(abs(dir.x), abs(dir.y)) + dirReduce);

    dir = min(vec2(FXAA_SPAN_MAX, FXAA_SPAN_MAX),
              max(vec2(-FXAA_SPAN_MAX, -FXAA_SPAN_MAX),
                  dir * rcpDirMin)) * texOffset;

    vec3 rgbA = 0.5 * (
        texture(scene, texCoord + dir * (1.0 / 3.0 - 0.5)).xyz +
        texture(scene, texCoord + dir * (2.0 / 3.0 - 0.5)).xyz);

    vec3 rgbB = rgbA * 0.5 + 0.25 * (
        texture(scene, texCoord + dir * -0.5).xyz +
        texture(scene, texCoord + dir * 0.5).xyz);

    float lumaB = dot(rgbB, luma);

    if ((lumaB < lumaMin) || (lumaB > lumaMax)) {
        FragColor = vec4(rgbA, 1.0);
    }
    else {
        FragColor = vec4(rgbB, 1.0);
    }
}