pmed#138 Initial CMake support. Intended to use as cmake subdirectory

Author: YarikTH

CMakeLists.txt

@@ -0,0 +1,15 @@
+cmake_minimum_required(VERSION 3.14)
+
+project(v8pp LANGUAGES CXX)
+
+list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}")
+
+# On Ubuntu 20.04 install package libnode-dev because libv8-dev is redirected there
+find_package(V8)
+
+# TODO: add warning flags setup
+# TODO: add option to skip tests targets
+
+add_subdirectory(v8pp)
+add_subdirectory(test)
+add_subdirectory(plugins)

FindV8.cmake

@@ -0,0 +1,72 @@
+# Based on https://raw.githubusercontent.com/nicehash/cpp-ethereum/master/cmake/Findv8.cmake
+#
+# Find v8
+#
+# Find the v8 includes and library
+# 
+# if you nee to add a custom library search path, do it via via CMAKE_PREFIX_PATH 
+# 
+# This module defines
+#  V8_INCLUDE_DIRS, where to find header, etc.
+#  V8_LIBRARIES, the libraries needed to use v8.
+#  V8_FOUND, If false, do not try to use v8.
+
+# only look in default directories
+find_path(V8_INCLUDE_DIR NAMES v8.h PATHS /usr/include/v8 DOC "v8 include dir")
+
+find_library(V8_LIBRARY NAMES v8 PATHS /usr/lib DOC "v8 library")
+
+set(V8_INCLUDE_DIRS ${V8_INCLUDE_DIR})
+set(V8_LIBRARIES ${V8_LIBRARY})
+
+# debug library on windows
+# same naming convention as in qt (appending debug library with d)
+# boost is using the same "hack" as us with "optimized" and "debug"
+if("${CMAKE_CXX_COMPILER_ID}" STREQUAL "MSVC")
+    find_library(V8_LIBRARY NAMES v8_base DOC "v8 base library")
+
+    find_library(
+        V8_NO_SNAPSHOT_LIBRARY
+        NAMES v8_nosnapshot
+        DOC "v8 nosnapshot library"
+    )
+
+    set(V8_LIBRARIES ${V8_LIBRARY} ${V8_NO_SNAPSHOT_LIBRARY})
+
+    find_library(V8_LIBRARY_DEBUG NAMES v8_based DOC "v8 base library")
+
+    find_library(
+        V8_NO_SNAPSHOT_LIBRARY_DEBUG
+        NAMES v8_nosnapshotd
+        DOC "v8 nosnapshot library"
+    )
+
+    set(V8_LIBRARIES
+        "ws2_32"
+        "winmm"
+        optimized
+        ${V8_LIBRARIES}
+        debug
+        ${V8_LIBRARY_DEBUG}
+        ${V8_NO_SNAPSHOT_LIBRARY_DEBUG}
+    )
+endif()
+
+# handle the QUIETLY and REQUIRED arguments and set V8_FOUND to TRUE
+# if all listed variables are TRUE, hide their existence from configuration view
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(V8 DEFAULT_MSG V8_INCLUDE_DIR V8_LIBRARY)
+mark_as_advanced(V8_INCLUDE_DIR V8_LIBRARY)
+
+if(V8_FOUND)
+    if(NOT TARGET V8::V8)
+        add_library(V8::V8 SHARED IMPORTED)
+
+        set_target_properties(
+            V8::V8
+            PROPERTIES
+                INTERFACE_INCLUDE_DIRECTORIES "${V8_INCLUDE_DIR}"
+                IMPORTED_LOCATION "${V8_LIBRARY}"
+        )
+    endif()
+endif()

plugins/CMakeLists.txt

@@ -0,0 +1,10 @@
+function(v8pp_add_plugin name)
+    add_library(plugin_${name} MODULE ${name}.cpp)
+
+    set_target_properties(plugin_${name} PROPERTIES OUTPUT_NAME "${name}" PREFIX "")
+    
+    target_link_libraries(plugin_${name} PRIVATE v8pp::v8pp)
+endfunction()
+
+v8pp_add_plugin(console)
+v8pp_add_plugin(file)

test/CMakeLists.txt

@@ -0,0 +1,8 @@
+# Test target
+file(GLOB v8pp_test_cpp *.cpp)
+
+list(SORT v8pp_test_cpp)
+
+add_executable(v8pp_test ${v8pp_test_cpp})
+
+target_link_libraries(v8pp_test PRIVATE v8pp::v8pp)

v8pp/CMakeLists.txt

@@ -0,0 +1,44 @@
+# Copy all headers to ${CMAKE_CURRENT_BINARY_DIR}/v8pp
+# It makes this repo a little bit submodule friendly
+set(V8PP_INCLUDES_DIR "${CMAKE_CURRENT_BINARY_DIR}/include")
+file(MAKE_DIRECTORY "${V8PP_INCLUDES_DIR}/v8pp")
+
+file(GLOB v8pp_hpp RELATIVE ${CMAKE_CURRENT_LIST_DIR} *.hpp)
+file(GLOB v8pp_ipp RELATIVE ${CMAKE_CURRENT_LIST_DIR} *.ipp)
+
+foreach(f ${v8pp_hpp};${v8pp_ipp})
+    set(_original "${CMAKE_CURRENT_LIST_DIR}/${f}")
+    set(_linkname "${V8PP_INCLUDES_DIR}/v8pp/${f}")
+    file(CREATE_LINK "${_original}" "${_linkname}" COPY_ON_ERROR)
+endforeach()
+
+# Header only library target
+add_library(v8pp-header-only INTERFACE)
+
+add_library(v8pp::v8pp-header-only ALIAS v8pp-header-only)
+
+target_include_directories(v8pp-header-only INTERFACE "${V8PP_INCLUDES_DIR}")
+
+target_compile_definitions(v8pp-header-only INTERFACE V8PP_HEADER_ONLY=1)
+
+target_compile_features(v8pp-header-only INTERFACE cxx_std_14)
+
+target_link_libraries(v8pp-header-only INTERFACE V8::V8)
+
+# Static library target
+file(GLOB v8pp_cpp *.cpp)
+list(SORT v8pp_cpp)
+
+add_library(v8pp STATIC ${v8pp_cpp})
+
+add_library(v8pp::v8pp ALIAS v8pp)
+
+target_include_directories(v8pp PUBLIC "${V8PP_INCLUDES_DIR}")
+
+target_compile_definitions(v8pp PUBLIC V8PP_HEADER_ONLY=0)
+
+target_compile_features(v8pp PUBLIC cxx_std_14)
+
+target_link_libraries(v8pp PUBLIC V8::V8 ${CMAKE_DL_LIBS})
+
+set_property(TARGET v8pp PROPERTY POSITION_INDEPENDENT_CODE ON)