Add ew files for typescript project embeds.

build/eslint_test.bzl

@@ -0,0 +1,28 @@
+load("@npm//:eslint/package_json.bzl", eslint_bin = "bin")
+
+def eslint_test(name, srcs, config, tsconfig, tags = []):
+    """Generates a test, which runs eslint.
+
+    Args:
+        name: target name
+        srcs: source files to lint
+        config: eslint config file
+        tsconfig: tsconfig file
+    """
+    eslint_bin.eslint_test(
+        name = name,
+        data = [
+            config,
+            tsconfig,
+            "//ts:eslintrc.base.json",
+            "//ts:tsconfig.base.json",
+            "//:node_modules/@typescript-eslint/eslint-plugin",
+        ] + srcs,
+        args = [
+            "--config $(location " + config + ")",
+        ] + [
+            "$(location " + src + ")"
+            for src in srcs
+        ],
+        tags = ["lint"] + tags,
+    )

build/wd_ts_project_embed.bzl

@@ -0,0 +1,65 @@
+load("@aspect_rules_ts//ts:defs.bzl", "ts_config", "ts_project")
+load("@workerd//:build/eslint_test.bzl", "eslint_test")
+load("@workerd//:build/wd_js_bundle.bzl", "wd_js_bundle")
+
+def _js_modules(ts_modules):
+    """convert dict with ts modules to dict with js modules."""
+    return dict([
+        (f.removesuffix(".ts") + ".js", m)
+        for f, m in ts_modules.items()
+        # .d.ts do not generate .js
+        if not f.endswith(".d.ts")])
+
+
+def wd_ts_project_embed(
+        name,
+        builtin_modules,
+        internal_modules,
+        tsconfig,
+        eslintrc,
+        tags = []):
+    """Define typescript project embedding compiled code into c++ library.
+
+    Args:
+      name: project name
+      srcs: .ts source files
+      tsconfig: tsconfig.json file for the project
+    """
+
+    srcs = list(builtin_modules) + list(internal_modules)
+
+    ts_config(
+        name = name + "@tsconfig",
+        src = tsconfig,
+        deps = ["//ts:tsconfig.base.json"],
+        tags = tags,
+    )
+
+    ts_project(
+        name = name,
+        srcs = srcs,
+        tsconfig = ":{}@tsconfig".format(name),
+        deps = ["//:node_modules/@cloudflare/workers-types"],
+        tags = tags,
+    )
+
+    wd_js_bundle(
+        name = name + "_bundle",
+        schema_id = "0xb7723ddc413262ab",
+        const_name = name + "Bundle",
+        builtin_modules = _js_modules(builtin_modules),
+        internal_modules = _js_modules(internal_modules),
+        tags = tags,
+        target_compatible_with = select({
+            "@//build/config:no_build": ["@platforms//:incompatible"],
+            "//conditions:default": [],
+        }),
+    )
+
+    eslint_test(
+        name = name + "@eslint",
+        srcs = srcs,
+        config = eslintrc,
+        tsconfig = tsconfig,
+        tags = tags,
+    )

samples/tcp/gopher.js

@@ -12,6 +12,8 @@
 // - curl localhost:8080/ # Retrieve the main segment in gopher.floodgap.com.
 // - curl localhost:8080/gstats # Retrieve the "gstats" segment.
 // - curl localhost:8080/gstats?use_proxy=1 # Retrieve the "gstats" segment using the configured proxy.
+import { connect } from 'cloudflare:sockets';
+
 export default {
   async fetch(req, env) {
     const gopherAddr = "gopher.floodgap.com:70";

src/workerd/server/BUILD.bazel

@@ -59,6 +59,7 @@ wd_cc_library(
         "@capnp-cpp//src/capnp:capnpc",
         "//src/workerd/io",
         "//src/workerd/jsg",
+        "//ts:cloudflareEdgeworker_bundle",
     ],
 )
 

src/workerd/server/workerd-api.c++

@@ -26,6 +26,8 @@
 #include <openssl/hmac.h>
 #include <openssl/rand.h>
 
+#include "ts/cloudflareEdgeworker_bundle.capnp.h"
+
 namespace workerd::server {
 
 JSG_DECLARE_ISOLATE_TYPE(JsgWorkerdIsolate,
@@ -350,6 +352,7 @@ kj::Own<jsg::ModuleRegistry> WorkerdApiIsolate::compileModules(
   }
 
   api::registerSocketsModule(*modules, getFeatureFlags());
+  modules->addBuiltinBundle(CLOUDFLARE_EDGEWORKER_BUNDLE);
 
   jsg::setModulesForResolveCallback<JsgWorkerdIsolate_TypeWrapper>(lock, modules);
 

ts/.gitignore

@@ -0,0 +1 @@
+node_modules/

ts/BUILD

@@ -0,0 +1,44 @@
+load("@workerd//:build/wd_ts_project_embed.bzl", "wd_ts_project_embed")
+
+# these will be accessible under "node:<name_without_extension>"
+node_modules = glob(["node/*.ts"])
+
+# these will be accessible under "node-internal:<name_without_extension>"
+node_internal_modules = glob(["node/internal/*.ts"])
+
+# these will be accessible under "cloudflare:<name_without_extension>"
+cloudflare_modules = glob(["cloudflare/*.ts"])
+
+# these will be accessible under "cloudflare-internal:<name_without_extension>"
+cloudflare_internal_modules = glob(["cloudflare/internal/*.ts"])
+
+wd_ts_project_embed(
+    # give bundle an "internal" name to be clear which one comes from workerd/edgeworker.
+    name = "nodeEdgeworker",
+    builtin_modules = dict([(
+        m,
+        "node:" + m.removeprefix("node/").removesuffix(".ts"),
+    ) for m in node_modules]),
+    eslintrc = "node/.eslintrc.json",
+    internal_modules = dict([(
+        m,
+        "node-internal:" + m.removeprefix("node/internal/").removesuffix(".ts"),
+    ) for m in node_internal_modules]),
+    tags = ["no-arm64"],
+    tsconfig = "node/tsconfig.json",
+)
+
+wd_ts_project_embed(
+    name = "cloudflareEdgeworker",
+    builtin_modules = dict([(
+        m,
+        "cloudflare:" + m.removeprefix("cloudflare/").removesuffix(".ts"),
+    ) for m in cloudflare_modules]),
+    eslintrc = "cloudflare/.eslintrc.json",
+    internal_modules = dict([(
+        m,
+        "cloudflare-internal:" + m.removeprefix("cloudflare/internal/").removesuffix(".ts"),
+    ) for m in cloudflare_internal_modules]),
+    tags = ["no-arm64"],
+    tsconfig = "cloudflare/tsconfig.json",
+)

ts/cloudflare/.eslintrc.json

@@ -0,0 +1,6 @@
+{
+  "extends": "../eslintrc.base.json",
+  "parserOptions": {
+    "project": "ts/cloudflare/tsconfig.json"
+  }
+}

ts/cloudflare/tsconfig.json

@@ -0,0 +1,14 @@
+{
+  "extends": "../tsconfig.base.json",
+  "compilerOptions": {
+    "types": ["@cloudflare/workers-types"],
+    "paths": {
+      "cloudflare:*": ["./*"],
+      "cloudflare-internal:*": ["./internal/*"],
+    }
+  },
+  "include": [
+    "*.ts",
+    "internal/*.ts"
+  ],
+}

ts/eslintrc.base.json

@@ -0,0 +1,24 @@
+{
+    "env": {
+        "es2022": true,
+        "worker": true
+    },
+    "extends": [
+        "plugin:@typescript-eslint/recommended",
+        "plugin:@typescript-eslint/recommended-requiring-type-checking",
+        "plugin:@typescript-eslint/strict"
+    ],
+    "overrides": [],
+    "parserOptions": {
+        "ecmaVersion": "latest",
+        "sourceType": "module"
+    },
+    "rules": {
+        "@typescript-eslint/explicit-function-return-type": "error",
+        "@typescript-eslint/explicit-member-accessibility": "error",
+        "@typescript-eslint/explicit-module-boundary-types": "error",
+        "@typescript-eslint/no-require-imports": "error",
+        "@typescript-eslint/prefer-enum-initializers": "error",
+        "@typescript-eslint/type-annotation-spacing": "error"
+    }
+}

ts/node/.eslintrc.json

@@ -0,0 +1,6 @@
+{
+  "extends": "../eslintrc.base.json",
+  "parserOptions": {
+    "project": "ts/node/tsconfig.json"
+  }
+}

ts/node/path.ts

@@ -0,0 +1,8 @@
+export function basename(path: string, ext?: string): string {
+  if (ext) {
+    throw new Error(`basename with ext not implemented: ${path} ${ext}`);
+  }
+
+  const idx = path.lastIndexOf("/");
+  return idx >= 0 ? path.substring(idx + 1) : path;
+}

ts/node/tsconfig.json

@@ -0,0 +1,14 @@
+{
+  "extends": "../tsconfig.base.json",
+  "compilerOptions": {
+    "types": ["@cloudflare/workers-types"],
+    "paths": {
+      "node:*": ["./*"],
+      "node-internal:*": ["./internal/*"],
+    }
+  },
+  "include": [
+    "*.ts",
+    "internal/*.ts"
+  ],
+}

src/cloudflare/tsconfig.json → ts/tsconfig.base.json

@@ -2,10 +2,9 @@
   "compilerOptions": {
     "target": "ESNext",
     "module": "ESNext",
-    "lib": [ "ESNext", "DOM" ],
+    "lib": ["ESNext"],
     "alwaysStrict": true,
     "strict": true,
-    "allowJs": true,
     "allowUnreachableCode": false,
     "allowUnusedLabels": false,
     "exactOptionalPropertyTypes": true,
@@ -18,17 +17,5 @@
     "noUnusedParameters": true,
     "strictNullChecks": true,
     "esModuleInterop": true,
-    "types": [
-      // todo: consume generated workerd types
-      // "@cloudflare/workers-types"
-    ],
-    "paths": {
-      "cloudflare:*": ["./*"],
-      "cloudflare-internal:*": ["./internal/*"]
-    }
-  },
-  "include": [
-    "*.ts",
-    "internal/*.ts"
-  ],
+  }
 }